创建在Excel宏其执行其他宏观每2秒

Question

我有一个名为UpdateMacro宏从更新我的数据库我的Excel

我想创建一个宏名为RepeatMacro它会自动执行UpdateMacro每2秒并且仅提供启动和停止按钮来启动和停止执行RepeatMacro。

怎么办？

Answer 1

谷歌为Application.OnTime

例如

Dim dtNextRunTime As Date 
dtNextRunTime = Now + TimeSerial(0,0,2) 
Application.OnTime dtNextRunTime, "MyProcedure", True 

要清除以前设置的过程，您需要保存调度的时间） dtNextRunTime以上），然后用：

Application.OnTime dtNextRunTime, "MyProcedure", False 

下面是一个示例VB模块方法StartSchedule/StopSchedule让你去：

Private m_dtScheduledTime As Date 
Private m_lDelaySeconds As Long 
Private m_bIsScheduled As Boolean 

Private Sub DoWork() 

    m_bIsScheduled = False 

    ' ... do your work 

    ' Reschedule at the same frequency once completed 
    StartSchedule m_lDelaySeconds, "DoWork" 

End Sub 

Public Sub StartSchedule(ByVal DelaySeconds As Long) 
    StopSchedule 
    m_lDelaySeconds = DelaySeconds 
    m_dtScheduledTime = Now + TimeSerial(0, 0, m_lDelaySeconds) 
    Application.OnTime m_dtScheduledTime, "DoWork", True 
    m_bIsScheduled = True 
End Sub 

Public Sub StopSchedule() 
    If m_bIsScheduled Then 
     Application.OnTime m_dtScheduledTime, "DoWork", False 
     m_bIsScheduled = False 
    End If 
End Sub 

Answer 2

这将运行UpdateMacro每两秒钟，假设UpdateMacro花费不到两运行几秒钟。

Sub RepeatMacro() 
    Dim lastRunTime 
    Do 
     lastRunTime = Now 
     Range("A1") = "Last run: " & Format(lastRunTime, "hh:nn:ss") 
     Call UpdateMacro 
     DoEvents 
     Application.Wait lastRunTime + TimeValue("00:00:02") 
    Loop 
End Sub 

Sub UpdateMacro() 
    Debug.Print "running UpdateMacro" 
End Sub 

编辑启动并从您的薄片停止RepeatMacro，使一个启动按钮和停止按钮，并把下面的代码你的表模块中。另外请注意，我在上面的RepeatMacro中添加了一个DoEvents。

Private Sub StartButton_Click() 
    Call RepeatMacro 
End Sub 

Private Sub StopButton_Click() 
    MsgBox "Stopped." 
    End 
End Sub 

现在只是说End是不好的做法，但你明白了。