安装后Inno IDE消除视图复选框

Question

安装完成后，安装程序会为用户提供一个标记为“View”的复选框选项，用户可以选择在完成安装后明显打开安装文件夹。我如何禁用此功能？

安装完成后，我不希望用户有“查看”任何选项。只需关闭安装程序即可。

UPDATE：这里是脚本：

; Script generated by the Inno Setup Script Wizard. 
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES! 

#define MyAppName "My App" 
#define MyAppVersion "1.0" 
#define MyAppPublisher "Blah, LLC" 
#define MyAppURL "http://www.blah.com/" 

[Setup] 
; NOTE: The value of AppId uniquely identifies this application. 
; Do not use the same AppId value in installers for other applications. 
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.) 
AppID={{f47ac10b-58cc-4372-a567-0e02b2c3d479} 
AppName={#MyAppName} 
AppVersion={#MyAppVersion} 
;AppVerName={#MyAppName} {#MyAppVersion} 
AppPublisher={#MyAppPublisher} 
AppPublisherURL={#MyAppURL} 
AppSupportURL={#MyAppURL} 
AppUpdatesURL={#MyAppURL} 
CreateAppDir=false 
LicenseFile=Release\EULA.rtf 
SetupIconFile=Release\bin\logo.ico 
Compression=lzma/Max 
SolidCompression=true 
AppCopyright=Blah, LLC 
AppVerName={#MyAppName} 
DisableFinishedPage=yes 
VersionInfoVersion=1.0 
VersionInfoCompany=Blah, LLC 
VersionInfoDescription=My description here. 
VersionInfoCopyright=2012 
VersionInfoProductName=My App 
VersionInfoProductVersion=1.0 

[Languages] 
Name: "english"; MessagesFile: "compiler:Default.isl" 

[Files] 
Source: Release\bin\glassfish-3.1.2; DestDir: {sd}\MyApp; Flags: ignoreversion recursesubdirs createallsubdirs external; 
; NOTE: Don't use "Flags: ignoreversion" on any shared system files 
Source: {src}\README.txt; DestDir: {tmp}; Attribs: ReadOnly; Flags: isreadme external dontcopy; 

[Types] 
Name: full; Description: "Full Installation"; 
Name: custom; Description: "Custom Installation"; Flags: IsCustom; 

[Components] 
Name: webserver; Description: "GlassFish 3.1.2 Application Server"; Types: full custom; ExtraDiskSpaceRequired: 100851712; 
Name: sqlserver; Description: "SQL Server Express 2008 R2"; ExtraDiskSpaceRequired: 745537536; Types: full custom; 
Name: sqlserver\sqlserver_x64; Description: "Microsoft SQL Server Express (x64)"; Flags: exclusive; Types: full custom; 
Name: sqlserver\sqlserver_x86; Description: "Microsoft SQL Server Express (x86)"; Flags: exclusive; Types: full custom; 

[Tasks] 
Components: webserver; Name: glassfishservice; Description: "Register the web server as a Windows Service."; GroupDescription: "Web Server Options"; 

[Run] 
Tasks: glassfishservice; Components: webserver; Filename: asadmin; Parameters: "create-service MyApp"; WorkingDir: "{sd}\MyApp\bin"; StatusMsg: "Creating GlassFish service."; 
Tasks: glassfishservice; Components: webserver; Filename: net; Parameters: "start ""MyApp GlassFish Server"""; StatusMsg: "Starting Windows service."; 
; https://blogs.oracle.com/foo/entry/automatic_starting_of_servers_in AND https://blogs.oracle.com/foo/entry/how_to_make_v3_platform 
Filename: SQLEXPRWT_x86_ENU.exe; WorkingDir: {src}\bin; Description: "Installs SQL Server 32-bit edition."; StatusMsg: "Installing SQL Server Express 2008..."; Components: sqlserver\sqlserver_x86; Flags: HideWizard 32bit; 
Filename: SQLEXPRWT_x64_ENU.exe; WorkingDir: {src}\bin; Description: "Installs SQL Server 64-bit edition."; StatusMsg: "Installing SQL Server Express 2008..."; Components: sqlserver\sqlserver_x64; Flags: HideWizard 64bit; 
Components: "sqlserver sqlserver\sqlserver_x64 sqlserver\sqlserver_x86"; Filename: sqlcmd; Parameters: "-S COMPUTER\SQLEXPRESS -i {sd}\bin\script.sql"; Description: "Creating database."; 

[InnoIDE_PostCompile] 
Name: "C:\Program Files\PowerISO\piso.exe"; Parameters: "create -o """"{#MyAppName} - v{#MyAppVersion}.iso"""" -add Release /"; Flags: CmdPrompt; 

[UninstallRun] 
Tasks: glassfishservice; Components: webserver; Filename: net; Parameters: "stop ""MyApp GlassFish Server"""; StatusMsg: "Stopping Windows service."; 
Tasks: glassfishservice; Components: webserver; Filename: asadmin; Parameters: "_delete-service MyApp"; WorkingDir: "{sd}\MyApp\bin"; StatusMsg: "Destroying GlassFish service."; 

[Dirs] 

Answer 1

如果这是一个InnoSetup安装，请检查您[Run]部分的postinstall条目，将其删除。 该postinstall在docs所定义：

安装后

Valid only in a [Run] section. Instructs Setup to create a checkbox on the Setup Completed wizard page. The user can uncheck or 

检查该复选框，从而选择是否该条目应当 处理或没有。此前该标志被称为showcheckbox。

完成页面上复选框的另一个原因是isreadme标志。从docs：

isreadme

文件是 “自述” 文件。只有一个安装文件可以有 这个标志。当文件具有此标志时，用户将询问他/她 是否想在完成安装 后查看自述文件。如果选择是，安装程序将使用文件类型的默认程序 打开文件。由于这个原因，自述文件 应该总是以类似于.txt，.wri或.doc的扩展名结尾。

注意，如果设置了重新启动用户的计算机（作为 结果安装文件旗restartreplace或者如果AlwaysRestart [Setup]段的指令是肯定的），用户将不会被给予 选项查看自述文件