Windows资源管理器复制时间基准

Question

我想基准我们公司的操作系统，其中一个步骤是计算需要多少时间才能将某些东西复制到某处，只需在浏览器下按ctrl-c/ctrl-v 。 因此，我想知道如何将批处理中的该操作脚本化几次，以便我可以执行时间，特别是如何使复制处理弹出窗口。我认为“rundll32 shell32.dll”涉及某种方式，但我不知道如何。

感谢

Answer 1

您既可以

• 使用直接从您的应用程序Windows用户界面自动化 API（http://en.wikipedia.org/wiki/Microsoft_UI_Automation）;

• ，或者你可以创建一个的AutoIt脚本（http://www.autoitscript.com/site/autoit/）

Answer 2

你可以使用VBScript做到这一点。请参阅Folder.CopyHere method页面上的脚本示例。有趣的是，Folder.CopyHere方法也可以将文件放入zip文件夹中。看看an example（如果没有其他原因，看看另一个真实世界的例子，如何使用CopyHere）。与scripting.filesystemobject复制功能不同，copyhere函数使用Windows UI API，如果存在，则提示进行替换，并显示文件复制对话框，就好像用户拖放一样。

下面是示例benchmark.vbs，将".\Ubi Caritas.mp3"复制到%temp% 100次，然后显示该操作花费的时间（以4位精度表示），以毫秒为单位。

set wShl = CreateObject("Wscript.Shell") 
tmp = wShl.ExpandEnvironmentStrings("%TEMP%") 
set wShl = nothing 
set oShl = CreateObject("shell.application") 
set fso = CreateObject("Scripting.FileSystemObject") 

set srcfile=fso.GetFile("Ubi Caritas.mp3") 
dest=tmp & "\" & srcfile.Name 

wscript.Echo "Testing copy speed from " & srcfile.Name & " (" & srcfile.size & " bytes) to " & dest 

' single copy 
msb4 = Timer 
call doCopy 
msafter = Timer 
wscript.Echo "1 copy took " & FormatNumber(msafter - msb4, 4, -2, -2, false) & " seconds." 

' 100 copies 
msb4 = Timer 
for i = 0 to 100 
    call doCopy 
next 
msafter = Timer 
wscript.Echo "100 copies took " & FormatNumber(msafter - msb4, 4, -2, -2, false) & " seconds." 

set destfile = nothing 
set oShl = nothing 
set fso = nothing 

sub doCopy 
    oShl.namespace(tmp).copyhere(srcfile.Name), 16 
    if isEmpty(destfile) then set destfile = fso.getFile(dest) 
    do until destfile.size = srcfile.size 
     wscript.sleep 10 
    loop 
    destfile.delete 
end sub 

输出示例：

C:\Users\me\Desktop>cscript /nologo benchmark.vbs 
Testing copy speed from Ubi Caritas.mp3 (2929371 bytes) to C:\Users\me\AppD 
ata\Local\Temp\Ubi Caritas.mp3 
1 copy took 0.0664 seconds. 
100 copies took 4.0430 seconds.