在Perl中，while循环通常比for循环快吗？

Question

我做了一个小实验，如下所示，它看起来像while循环比Perl中的for循环更快。但是由于这个实验比较粗糙，主题可能比看起来要复杂得多，所以我想听听你对此有何评论。 一如既往的感谢您的任何意见和建议:)

在以下两个小脚本中，我尝试了while和for循环来分别计算100,000的阶乘。具有while循环的那个花费了57分17秒来完成，而for循环等效花费了1小时7分54秒。

脚本有while循环：具有用于循环

use strict; 
use warnings; 
use bigint; 

my $now = time; 

my $n = shift; 
my $s = 1; 

while(1){ 
$s *= $n; 
$n--; 
last if $n==2; 
} 

print $s*$n; 
$now = time - $now; 
printf("\n\nTotal running time: %02d:%02d:%02d\n\n", int($now/3600), 
      int(($now % 3600)/60), int($now % 60)); 

脚本：

use strict; 
use warnings; 
use bigint; 

my $now = time; 

my $n =shift; 
my $s=1; 

for (my $i=2; $i<=$n;$i++) { 
$s = $s*$i; 
} 

print $s; 
$now = time - $now; 
printf("\n\nTotal running time: %02d:%02d:%02d\n\n", int($now/3600), 
      int(($now % 3600)/60), int($now % 60)); 

Answer 1

这些循环并不等同，您主要是在抖动bigint包，它本身与for vs while无关。

while循环使用符号'$s *= $i'，但for循环使用'$s = $s * $i'。 这很简单，足以证明这些不相同。另外，一个循环计数;另一个倒数。这会影响乘数的大小。这是二阶效应 - 但不是完全可以忽略的。

[更新：修改为仅显示代码的一个版本，并具有亚秒的时间。有时候可以认为打印应该从时间计算中排除;这让事情变得更加混乱，所以我没有打扰过。我已修复了以前版本中的错误：循环4与循环3相同 - 现在不是。我也对输出格式进行了调整（尽管可以改进次秒处理 - 这是读者的一项练习），并且有更好的“进度报告”。]

在一台Mac Mini（雪豹10.6.2）的时序结果：

Count up $s *= $i:  00:00:12.663337 
Count up $s = $s * $i: 00:00:20.686111 
Count down $s *= $i:  00:00:14.201797 
Count down $s = $s * $i: 00:00:23.269874 

脚本：

use Time::HiRes qw(gettimeofday); 
use strict; 
use warnings; 
use bigint; 
use constant factorial_of => 13000; 

sub delta_t 
{ 
    my($tag, $t1, $t2) = @_; 
    my($d) = int($t2 - $t1); 
    my($f) = ($t2 - $t1) - $d; 
    my($s) = sprintf("%.6f", $f); 
    $s =~ s/^0//; 
    printf "%-25s %02d:%02d:%02d%s\n", 
      $tag, int($d/3600), int(($d % 3600)/60), int($d % 60), $s; 
} 

my $t1 = gettimeofday; 

{ 
    my $n = factorial_of; 
    my $s = 1; 
    for (my $i = 2; $i <= $n; $i++) 
    { 
     $s *= $i; 
    } 
    print "$s\n: Loop 1\n"; 
} 

my $t2 = gettimeofday; 
delta_t('Count up $s *= $i:',  $t1, $t2); 

{ 
    my $n = factorial_of; 
    my $s = 1; 
    for (my $i = 2; $i <= $n; $i++) 
    { 
     $s = $s * $i; 
    } 
    print "$s\n: Loop 2\n"; 
} 

my $t3 = gettimeofday; 
delta_t('Count up $s *= $i:',  $t1, $t2); 
delta_t('Count up $s = $s * $i:', $t2, $t3); 

{ 
    my $n = factorial_of; 
    my $s = 1; 
    for (my $i = $n; $i > 1; $i--) 
    { 
     $s *= $i; 
    } 
    print "$s\n: Loop 3\n"; 
} 

my $t4 = gettimeofday; 
delta_t('Count up $s *= $i:',  $t1, $t2); 
delta_t('Count up $s = $s * $i:', $t2, $t3); 
delta_t('Count down $s *= $i:',  $t3, $t4); 

{ 
    my $n = factorial_of; 
    my $s = 1; 
    for (my $i = $n; $i > 1; $i--) 
    { 
     $s = $s * $i; 
    } 
    print "$s\n: Loop 4\n"; 
} 

my $t5 = gettimeofday; 
delta_t('Count up $s *= $i:',  $t1, $t2); 
delta_t('Count up $s = $s * $i:', $t2, $t3); 
delta_t('Count down $s *= $i:',  $t3, $t4); 
delta_t('Count down $s = $s * $i:', $t4, $t5); 

---

这里还有一个更紧凑版本上面的代码扩展为测试'while'循环以及'for'循环。它也处理大部分时间问题。唯一不理想的是（它）使用了一些全局变量，并且我稍微在代码中引用了代码，因此它全部适合一行而不触发滚动条（反正在我的显示器上）。显然，只需要多做一些工作，就可以将测试包装到一个数组中，以便迭代地完成测试 - 通过对数组中的信息运行计时器函数的数组进行循环。等等...这是一个SMOP - 简单的编程问题。 （它会打印阶乘的MD5哈希，而不是阶乘本身，因为它比较容易比较结果等等。当我重构上面的代码时，它指出了一些错误。是的，MD5是不安全的 - 但我不使用它的安全性，只是被发现的无意更改）压缩，以避免断行

use Time::HiRes qw(gettimeofday); 
use Digest::MD5 qw(md5_hex); 
use strict; 
use warnings; 
use bigint; 
use constant factorial_of => 13000; 

my ($s, $i); 

my $l1 = sub {my($n) = @_; for ($i = 2; $i <= $n; $i++) { $s *= $i;  }}; 
my $l2 = sub {my($n) = @_; for ($i = 2; $i <= $n; $i++) { $s = $s * $i; }}; 
my $l3 = sub {my($n) = @_; for ($i = $n; $i > 1; $i--) { $s *= $i;  }}; 
my $l4 = sub {my($n) = @_; for ($i = $n; $i > 1; $i--) { $s = $s * $i; }}; 
my $l5 = sub {my($n) = @_; $i = 2; while ($i <= $n) { $s *= $i;  $i++; }}; 
my $l6 = sub {my($n) = @_; $i = 2; while ($i <= $n) { $s = $s * $i; $i++; }}; 
my $l7 = sub {my($n) = @_; $i = $n; while ($i > 1) { $s *= $i;  $i--; }}; 
my $l8 = sub {my($n) = @_; $i = $n; while ($i > 1) { $s = $s * $i; $i--; }}; 

sub timer 
{ 
    my($n, $code, $tag) = @_; 
    my $t1 = gettimeofday; 
    $s = 1; 
    &$code(factorial_of); 
    my $t2 = gettimeofday; 
    my $md5 = md5_hex($s); 
    printf "Loop %d: %-33s %09.6f (%s)\n", $n, $tag, $t2 - $t1, $md5; 
} 

my $count = 1; 
timer($count++, $l1, 'for - Count up $s *= $i:'); 
timer($count++, $l2, 'for - Count up $s = $s * $i:'); 
timer($count++, $l3, 'for - Count down $s *= $i:'); 
timer($count++, $l4, 'for - Count down $s = $s * $i:'); 
timer($count++, $l5, 'while - Count up $s *= $i:'); 
timer($count++, $l6, 'while - Count up $s = $s * $i:'); 
timer($count++, $l7, 'while - Count down $s *= $i:'); 
timer($count++, $l8, 'while - Count down $s = $s * $i:'); 

输出示例（MD5校验 - 全部价值为584b3ab832577fd1390970043efc0ec8）：

Loop 1: for - Count up $s *= $i:  12.853630 (584b3ab8...3efc0ec8) 
Loop 2: for - Count up $s = $s * $i: 20.854735 (584b3ab8...3efc0ec8) 
Loop 3: for - Count down $s *= $i:  14.798155 (584b3ab8...3efc0ec8) 
Loop 4: for - Count down $s = $s * $i: 23.699913 (584b3ab8...3efc0ec8) 
Loop 5: while - Count up $s *= $i:  12.972428 (584b3ab8...3efc0ec8) 
Loop 6: while - Count up $s = $s * $i: 21.192956 (584b3ab8...3efc0ec8) 
Loop 7: while - Count down $s *= $i:  14.555620 (584b3ab8...3efc0ec8) 
Loop 8: while - Count down $s = $s * $i: 23.790795 (584b3ab8...3efc0ec8) 

我。在相应的'for'循环中始终看到'while'循环的小惩罚（< 1％），但我没有很好的解释它。

Answer 2

我会倒下震惊，如果确实存在，而之间的循环任何“真正”的区别。假设他们正在做“完全一样”的事情，他们应该被解释者优化成或多或少相同。

我敢打赌，这种差异可能只不过是在两次执行期间为资源争夺不同的其他进程罢了。

即使存在差异，也不要陷入The Sad Tragedy of Micro-Optimization Theater。

Answer 3

基准测试的一个关键是简化。提出的问题是for与while的速度。但是实验涉及几个不必要的复杂性。

• 这两个循环并不像它们可能的那样相似。一个使用$s *= $n，另一个使用$s = $s * $i（正如Jonathan Leffler指出的那样）。一个使用$n--，另一个使用$i++（谁知道他们的速度是否不同？）。

• 如果我们对for与while感兴趣，则不需要涉及bigint。这只会混淆这个话题。特别是，您的while脚本仅取决于一个bigint对象（$s），而for脚本使用其中两个（$s和$i）。 for脚本比较慢，这并不让我感到惊讶。

重写你的循环，以尽可能相似，保持阶乘足够小，这样你就不必使用bigint，并使用Benchmark模块。然后，您可以进行一场公平的比赛，即for与while。我会很好奇，看看你找到了什么。