如何用Perl执行多个替换？

Question

我有Perl代码：

my $s = "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog"; 

我想替换每个+空间和dog与cat。

我有这样的正则表达式：

$s =~ s/\+(.*)dog/ ${1}cat/g; 

但是，这只是+和最后dog第一次出现的匹配。

Answer 1

可以使用“E”改性剂在s///表达式的第二部分来执行代码。

$s =~ s/(\+)|(dog)/$1 ? ' ' : 'cat'/eg; 

如果$1为真，则表示匹配\+，所以它替换的空间;否则它会替代“猫”。

Answer 2

答案很简单 - 使用2线!:

$s =~ s/+/ /g; 
$s =~ s/dog/cat/g; 

它很可能在一个行完成与“非贪婪”匹配，但是这应该做的伎俩

Answer 3

两个正则表达式可能使你的生活轻松了许多：

$s =~ s/\+/ /g; 
$s =~ s/dog/cat/g; 

下面的比赛“+”，后面一堆东西，其次是“狗”。另外，“+”在技术上是一个元字符。

/+(.*)dog/ 

Answer 4

散列可以做你想做的：

#!/usr/bin/perl 

use strict; 
use warnings; 

my $s = "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog"; 

my %replace = (
    "+" => " ", 
    dog => "cat", 
); 

$s =~ s/([+]|dog)/$replace{$1}/g; 

print "$s\n"; 

在我看到你所关心的性能的意见，这两个正则表达式的解决方案是更好的性能。这是因为任何适用于一个正则表达式的解决方案都需要使用捕获（这会减慢正则表达式）。

这里有一个基准的结果：

eval: The quick brown fox jumps over the lazy cat that is my cat 
hash: The quick brown fox jumps over the lazy cat that is my cat 
two: The quick brown fox jumps over the lazy cat that is my cat 
     Rate hash eval two 
hash 33184/s -- -29% -80% 
eval 46419/s 40% -- -72% 
two 165414/s 398% 256% -- 

我用下面的基准：

#!/usr/bin/perl 

use strict; 
use warnings; 

use Benchmark; 

my $s = "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog"; 

my %replace = (
    "+" => " ", 
    dog => "cat", 
); 

my %subs = (
    hash => sub { 
     (my $t = $s) =~ s/([+]|dog)/$replace{$1}/g; 
     return $t; 
    }, 
    two => sub { 
     (my $t = $s) =~ s/[+]/ /g; 
     $t =~ s/dog/cat/g; 
     return $t; 
    }, 
    eval => sub { 
     (my $t = $s) =~ s/(\+)|(dog)/$1 ? ' ' : 'cat'/eg; 
     return $t; 
    }, 
); 

for my $k (sort keys %subs) { 
    print "$k: ", $subs{$k}(), "\n"; 
} 

Benchmark::cmpthese -1, \%subs; 

Answer 5

如果速度是重要的，你应该有两行坚持。但是，当我需要立即执行多个替换时，我通常更关心便利性，所以我使用Chas所建议的散列。欧文斯。与双线相比，两个优点是易于修改，并且其行为与预期相同（例如，当“猫”替代“猫”时，“猫”替代）。

然而，我感到非常懒手工编写的正则表达式，喜欢组装它与加盟，并使用地图逃避的东西：

#!/usr/bin/perl 

use strict; 
use warnings; 

my $s = "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog"; 

my %replace = (
    "+" => " ", 
    dog => "cat", 
); 

my $regex = join "|", 
    #use quotemeta to escape special characters 
    map { quotemeta } 
    #reverse sort the keys because "ab" =~ /(a|ab)/ returns "a" 
    sort { $b cmp $a } keys %replace; 

#compiling the regex before using it prevents 
#you from having to recompile it each time 
$regex = qr/$regex/; 

$s =~ s/($regex)/$replace{$1}/g; 

print "$s\n"; 

Answer 6

Perl的5.14和更新与能力链换人一个非破坏性的任务，所以你可以用一块石头杀死3只鸟：做你的两个全局替换，并将结果赋给一个新的变量而不修改你的原始变量。

my $s = "The+quick+brown+fox+jumps+over+the+lazy+dog+that+is+my+dog"; 
my $result = $s =~ s/+/ /gr 
       =~ s/dog/cat/gr; 

将取代所有的+空间和与cat替换每dog，将结果分配到一个新的变量。在一个班轮。