Excel的VBA - 搜索，偏移，更换

Question

我有一个设置与板材中的列列d和重置价值的唯一标识符F.我需要：

• 遍历所有序列号在片settings列d
• 找到具有相同序列的行中片test塔A
• 得到settings F列
• 替换值替换在列B中的数据上test片，在同一行中作为先前击发阻铁高等教育委员会串行

听起来很简单，但与下面的代码定义for和to语句时，我得到一个类型不匹配错误。

Sub Replace_List() 
Dim rList As Range, cell As Range, n As Long 

    Application.ScreenUpdating = False 

    With ThisWorkbook.Sheets("Settings") 
     Set rList = .Range("D4", .Range("D" & Rows.Count).End(xlUp)) 
    End With 

    For Each cell In rList 
     For n = cell.Value To cell.Offset(0, 2).Value Step 1 
      ThisWorkbook.Sheets("test").Columns("B:B").Replace What:=n, _ 
           Replacement:=cell.Offset(0, 2).Value, _ 
           LookAt:=xlWhole 
     Next n 
    Next cell 

    Application.ScreenUpdating = True 

    MsgBox "Replaced all items from the list.", vbInformation, "Replacements Complete" 

End Sub 

任何指针，我在做什么错误在这里赞赏。 谢谢， A2K

编辑 如下截图：

设置 - 我找了调查ID，并想取代原日期与正确一个

Answer 1

我相信您希望使用Find查找每个匹配项，然后使用找到的位置的Offset替换该值：

Sub Replace_List() 
    Dim rList As Range, cel As Range, n As Long 
    Dim fnd As Range 
    Dim fndFirst As String 

    Application.ScreenUpdating = False 

    With ThisWorkbook.Sheets("Settings") 
     Set rList = .Range("D4", .Range("D" & .Rows.Count).End(xlUp)) 
    End With 

    For Each cel In rList 
     Set fnd = ThisWorkbook.Worksheets("test").Columns("A:A").Find(What:=cel.Value, LookAt:=xlWhole) 
     If Not fnd Is Nothing Then 
      fndFirst = fnd.Address 
      Do 
       fnd.Offset(0, 1).Value = cel.Offset(0, 2).Value 
       Set fnd = ThisWorkbook.Worksheets("test").Columns("A:A").FindNext(After:=fnd) 
      Loop While fnd.Address <> fndFirst 
     End If 
    Next 

    Application.ScreenUpdating = True 

    MsgBox "Replaced all items from the list.", vbInformation, "Replacements Complete" 

End Sub