Excel VBA：如何打开最近的excel文件

Question

我在指定的路径上下载文件，但每次打开最近的文件时，我都必须将最近的文件重命名为我已设置的指定名称宏。

只要文件的路径没有改变，我希望宏打开最近的文件。例如，给定两个文件my_file_fb和my_file_fb（1），我想打开最近下载的文件。

Answer 1

按我的意见，这个功能应该做的伎俩：

Public Function MostRecentFile(ByVal searchDirectory As String, ByVal wildCard As String) As String 
    '''Returns the most recent file in searchDirectory, which matches wildCard criteria 
    Dim strFile As String      'holds the name of the file we're currently looking at 
    Dim mostRecent As Date      'holds the date of creation for the most recent file 
    Dim currDate As Date       'date of creation for the current file 
    Dim mostRecentPath As String     'path of file with most recent date 

    strFile = Dir(searchDirectory & wildCard) 'look for file in directory which matches wildcard 
    Do While Len(strFile) > 0     'loop until Dir returns empty quotes (no files) 
     currDate = FileDateTime(searchDirectory & strFile) 
     If currDate > mostRecent Then   'check whether current file is more recent than previous files 
      mostRecent = currDate    'if so, update most recent date and file 
      mostRecentPath = searchDirectory & strFile 
     End If 
     strFile = Dir       'move to next file in directory 
    Loop 

    If mostRecent = 0 Then      'check whether any files were returned 
     MostRecentFile = "No files match '" & searchDirectory & wildCard & "'" 
    Else 
     MostRecentFile = mostRecentPath 
    End If 
End Function 

这需要输入字符串searchDirectory和wildCard，第一个指定要看看在哪个文件夹，第二个指定文件搜索的类型。

例如

MostRecentFile("C:/Users/[USERNAME]/Downloads/", "*.xls") 

返回路径从".xlsm",".xls",".xlsx"最近的文件（Excel文件）在您的下载文件夹作为String

我已经添加代码注释，所以希望您能够了解每一步都做