如何在xsl翻译时忽略命名空间

Question

我有一个如下所示的xml。

<?xml version="1.0" encoding="UTF-8"?> 
<books xmlns="http://www.books.com/SRK"> 
    <name>English</name> 
</books 

我需要使用xsl进行翻译后的以下输出。

<?xml version="1.0" encoding="UTF-8"?> 
<books> 
    <name>English</name> 
</books> 

我需要一个xsl来忽略命名空间。我尝试了一些东西，但它没有与命名空间一起工作。

我需要你的帮助。你的帮助将不胜感激。

Answer 1

这种转变：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="@*|node()[not(self::*)]"> 
    <xsl:copy/> 
</xsl:template> 

<xsl:template match="*"> 
    <xsl:element name="{local-name()}"> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

当应用于提供的XML文档：

<books xmlns="http://www.books.com/SRK"> 
    <name>English</name> 
</books> 

产生想要的，正确的结果：

<books> 
    <name>English</name> 
</books> 

Answer 2

其工作只有当我包括上述模板，如果我添加一些其他模板比以上一个，那么翻译是不是工作。没有模板得到执行。

可能您错过了book元素的名称空间声明。例如：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:b="http://www.books.com/SRK" 
    exclude-result-prefixes="b"> 

    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

     <!-- @dimitre's answer templates --> 

    <xsl:template match="b:name"> 
      <!-- your template for name --> 
    </xsl:template> 

</xsl:stylesheet> 

此外，请务必使用local-name()函数来获取元素的名称，没有相关的命名空间。

---

例

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:b="http://www.books.com/SRK" 
    exclude-result-prefixes="b"> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/> 


    <xsl:template match="b:input"> 
     <xsl:element name="{local-name(.)}"> 
       <xsl:apply-templates select="b:name"/> 
     </xsl:element> 
    </xsl:template> 

    <xsl:template match="b:name"> 
     <xsl:element name="{local-name()}"> 
      <xsl:value-of select="."/> 
     </xsl:element> 
      <lhs> 
       <xsl:apply-templates select="following-sibling::b:lhs/b:evaluate"/> 
      </lhs> 
    </xsl:template> 

    <xsl:template match="b:evaluate"> 
     Something to evaluate...  
    </xsl:template> 

</xsl:stylesheet> 

得到：

<?xml version="1.0" encoding="UTF-8"?> 
<input> 
<name>English</name> 
<lhs> 
     Something to evaluate...  
    </lhs> 
</input> 

---

第二示例

您可以创建一个名为local @ identity.xsl的单独转换，其中包含@Dimitre解决方案。然后你可以在你的转换中导入它。因为你有一个命名空间，搭配元素，你必须改变所有您的XPath，包括您将在变换声明前缀，如下面的例子：

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:brl="http://www.xyz.com/BRL" 
    exclude-result-prefixes="brl" 
    version="1.0"> 

    <xsl:import href="local-identity.xsl"/> 

    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 


    <xsl:template match="/brl:rule"> 
    <!-- do your staff, select using brl prefix --> 
    <xsl:apply-templates/> 
    </xsl:template> 

</xsl:stylesheet>