如何使用XSLT来创造独特的价值

Question

我有这样的XML：

<items> 
    <item> 
    <products> 
     <product>laptop</product> 
     <product>charger</product> 
    </products> 
    </item> 
    <item> 
    <products> 
     <product>laptop</product> 
     <product>headphones</product> 
    </products> 
    </item> 
</items> 

我希望它输出像

 
laptop 
charger 
headphones 

我试图用distinct-values()但我猜即时通讯做错了什么。谁能告诉我如何使用distinct-values()来实现这个目标？谢谢。

<xsl:template match="/">    
    <xsl:for-each select="//products/product/text()"> 
    <li> 
     <xsl:value-of select="distinct-values(.)"/> 
    </li>    
    </xsl:for-each> 
</xsl:template> 

但它给我的输出是这样的：

<li>laptop</li> 
<li>charger</li> 
<li>laptop></li> 
<li>headphones</li> 

Answer 1

一种XSLT 1.0使用溶液和generate-id()函数来获取不同的值：

<?xml version="1.0" encoding="UTF-8"?> 
    <xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/> 

<xsl:key name="product" match="/items/item/products/product/text()" use="." /> 

<xsl:template match="/"> 

    <xsl:for-each select="/items/item/products/product/text()[generate-id() 
             = generate-id(key('product',.)[1])]"> 
    <li> 
     <xsl:value-of select="."/> 
    </li> 
    </xsl:for-each> 

</xsl:template> 

</xsl:stylesheet> 

Answer 2

distinct-values(//product/text())

Answer 3

你不想 “输出（不同的值）”，而是“换每个（distinct-值）“：

<xsl:template match="/">    
    <xsl:for-each select="distinct-values(/items/item/products/product/text())"> 
    <li> 
     <xsl:value-of select="."/> 
    </li> 
    </xsl:for-each> 
</xsl:template> 

Answer 4

下面是我在过去使用的XSLT 1.0的解决方案，我认为这是比使用generate-id()功能更简洁（和可读性）。

<xsl:template match="/">   
    <ul> 
     <xsl:for-each select="//products/product[not(.=preceding::*)]"> 
     <li> 
      <xsl:value-of select="."/> 
     </li> 
     </xsl:for-each>    
    </ul> 
    </xsl:template> 

返回：

<ul xmlns="http://www.w3.org/1999/xhtml"> 
    <li>laptop</li> 
    <li>charger</li> 
    <li>headphones</li> 
</ul> 

Answer 5

我来到这个问题与Sitecore的XSL渲染工作时。使用key（）的方法和使用前一轴的方法都执行得非常缓慢。我最终使用了类似于key（​​）的方法，但不需要使用key（）。它执行得非常快。

<xsl:variable name="prods" select="items/item/products/product" /> 
<xsl:for-each select="$prods"> 
    <xsl:if test="generate-id() = generate-id($prods[. = current()][1])"> 
    <xsl:value-of select="." /> 
    <br /> 
    </xsl:if> 
</xsl:for-each>