Perl哈希和数组

Question

我有一个28个元素的数组。

我将数组内容复制到哈希中。

如果我尝试打印散列，它不显示所有的键和值。

代码如下给出

@new; 
%hash = @new; 
foreach $food (keys %hash) 
{ 
$color = $hash{$food}; 
print "$food is $color.\n"; 
} 

输出是::

attribute is Mandatory. 
min is 0X00. 
value is 778. 
max is 9940486857. 
name is Security_header. 
type is nibble. 

数组@new内容，

name Protocol_discriminator attribute Mandatory value 778 min 0X00 max 994048685 value 7 min 0 max F name Security_header attribute Mandatory type nibble value 778 min 0X00 max 9940486857 

我想在阵列中的所有内容，以被复制到散列中并被打印，如果我尝试遍历散列。但是一些只有部分数组内容被复制到哈希中。

任何人都可以帮助克服这个问题。我在过去两天挣扎着。

谢谢 Senthil。

Answer 1

简单的答案：散列应该被认为是一个关联数组。
有一个唯一键，每个键都有一个值（可以是散列）。

您的问题：每次遇到已存在的密钥时，都会替换该值。

---

解决方案：

#!/usr/bin/perl -w  

use strict; 

    sub main{ 
     $" = ", ";           # format array output 

     my %hash; 
     my @arr = (['color' ,'red' ] 
        , ['color' ,'blue'] 
        , ['size' ,'1' ] 
        , ['size' ,'2' ] 
        ); 

     foreach my $rcd (@arr) { 
     push @{$hash{$$rcd[0]}} , $$rcd[1]; 
     }   

     print "@{$hash{color}} \n";      # prints: red, blue 
    }  

    main(); 

Answer 2

您有多个具有相同名称的密钥，因此您正在覆盖数据。

您需要重新考虑您的方法。

可能你需要一个更聪明的算法来构造你的散列（例如把值放在数组ref中而不仅仅是一个简单的值）。可能你需要忘掉哈希，并且用一个for循环遍历整个数组，循环每次增加2。

Answer 3

@new阵列中的信息表明您需要更丰富的数据结构。我不知道你的问题的细节，但这里是我看到的结构。

my @data = (
    # Each data item is a hash reference, with four 
    # possible keys: name, attribute, type, and vals. 
    # I added the 'vals' key to handle the other information. 
    { 
     name  => 'Protocol_discriminator', 
     attribute => 'Mandatory', 
     type  => undef, 
     # The 'vals' key points to an array reference. 
     # That array contains a list of hash references. 
     vals => [ 
      { value => 778, min => '0X00', max => 994048685 }, 
      { value => 7, min =>  0, max =>  'F' }, 
     ], 
    }, 

    # Another data item. 
    { 
     name  => 'Security_header', 
     attribute => 'Mandatory', 
     type  => 'nibble', 
     vals => [ 
      { value => 778, min => '0X00', max => 9940486857 }, 
     ], 
    }, 
); 

要学习如何与复杂的数据结构的工作，看到perlreftut，perldsc和perllol。

此外，您的脚本应始终包含use strict和use warnings。

Answer 4

让我们改变的@new演示显示是怎么回事：

my @new = qw/ 
    attribute Mandatory 
    attribute Mandatory 
    max  994048685 
    max  9940486857 
    max  F 
    min  0 
    min  0X00 
    min  0X00 
    name  Protocol_discriminator 
    name  Security_header 
    type  nibble 
    value  7 
    value  778 
    value  778 
/; 

Perl的哈希键是唯一的，所以分配到@new时%hash，对于给定键的最后一个值“获胜。”举个简单的例子

$ perl -le '%h = qw/1 a 1 b 1 c/; print $h{1}' 
c

既然你有相同的密钥多个值，使用一个数据结构，可以处理：

my %hash; 
for (my $i = 0; $i < @new; $i += 2) { 
    my($name,$val) = @new[$i,$i+1]; 
    push @{ $hash{$name} } => $val; 
} 

如果你不介意的破坏@new，代码可以多一点惯用：

while (@new) { 
    my($name,$val) = splice @new, 0, 2; 
    push @{ $hash{$name} } => $val; 
} 

这意味着与给定的键在%hash相关联的每个值是一个参考转换为值的数组。 push运算符需要一个数组而不是引用，所以我们使用@{ ... }来解引用它。

如果您不熟悉Perl参考资料，请务必阅读perlref和perllol文档。打印在%hash值

的一种方式是

foreach my $name (sort keys %hash) { 
    print "$name = [@{ $hash{$name} }]\n"; 
} 

输出：

attribute = [Mandatory Mandatory] 
max = [994048685 9940486857 F] 
min = [0 0X00 0X00] 
name = [Protocol_discriminator Security_header] 
type = [nibble] 
value = [7 778 778]

用于打印和调试复杂的数据结构的另一种方便的技巧是Data::Dumper模块：

use Data::Dumper; 
print Dumper \%hash; 

打印

$VAR1 = { 
      'attribute' => [ 
          'Mandatory', 
          'Mandatory' 
         ], 
      'value' => [ 
         '7', 
         '778', 
         '778' 
        ], 
      'min' => [ 
        '0', 
        '0X00', 
        '0X00' 
        ], 
      'name' => [ 
         'Protocol_discriminator', 
         'Security_header' 
        ], 
      'max' => [ 
        '994048685', 
        '9940486857', 
        'F' 
        ], 
      'type' => [ 
         'nibble' 
        ] 
     };