QML：将滚动条连接到ListView

Question

我遇到ListView的问题。 ListView太长，并且它的一部分出现在窗口之外，但我无法附加滚动条。我尝试了许多不同的组合。我认为这个问题在于高度参数，但是如果删除它，ListView只显示第一个条目。

Column{ 
    anchors.fill: parent 
    Row{ 
     id: buttonsRow 
      Button{ 
       text: "Open dump file" 
       onClicked: fileDialog.visible = true 
      } 
      Button{ 
       text: "Copy raw data to clipboard" 
      } 
    } 
    ListView{ 
     id: listView 
     anchors.top: buttonsRow.bottom 
     height: contentHeight 
     //clip: true 
     flickableDirection: Flickable.VerticalFlick 
     boundsBehavior: Flickable.StopAtBounds 
     interactive: true 
     model: ListModel{ 
      id: listModel 
     } 
     delegate: MDelegate{} 
    } 
} 

有什么办法让它滚动吗？

Answer 1

设置height到contentHeight可能是问题所在。这会使ListView与其所有物品的高度相结合。只有当视图的高度小于其内容的高度时，滚动条才起作用。

这是一个使用的布局，而不是一种方法：

import QtQuick 2.8 
import QtQuick.Controls 2.1 
import QtQuick.Layouts 1.3 

ApplicationWindow { 
    width: 400 
    height: 300 
    visible: true 

    ColumnLayout { 
     anchors.fill: parent 

     RowLayout { 
      id: buttonsRow 
      Button { 
       text: "Open dump file" 
      } 
      Button { 
       text: "Copy raw data to clipboard" 
      } 
     } 

     ListView { 
      id: listView 
      flickableDirection: Flickable.VerticalFlick 
      boundsBehavior: Flickable.StopAtBounds 
      model: 100 
      clip: true 
      delegate: ItemDelegate { 
       text: modelData 
      } 

      Layout.fillWidth: true 
      Layout.fillHeight: true 

      ScrollBar.vertical: ScrollBar {} 
     } 
    } 
} 

Answer 2

我不明白，在你发布的代码，你到哪儿去连接一个滚动条都没有。实际上你需要包括ScrollBar组件在你的ListView，像这样：

ListView { 
     id: listView 
     ScrollBar.vertical: ScrollBar { 
     active: true 
     } 
    } 

见在https://doc.qt.io/qt-5/qml-qtquick-controls2-scrollbar.html