如何正确使用数组，而不是使用动态标量变量

我有这种类型的数据，需要（1）检索每个内部的第一个元素（每个“数字集群”中的5个元素，用“：”分隔）簇和（2）每组3个元素对检索到的元素进行分组。如何正确使用数组，而不是使用动态标量变量

chr1 69270 . A G 1/1:208,34:244:14.96:118,15,0 0/1:186,51:241:8.72:80,0,9 0/0:226,1:236:3.01:0,3,30 ./. 1/1:209,35:250:12:116,12,0 ./. 1/1:186,53:242:14.97:126,15,0 0/0:245,0:248:3.01:0,3,33 1/1:182,60:243:23.95:201,24,0

我相信有更好的方法来做到这一点。但是到现在为止，我只能想到使用残酷的武力，这总是很糟糕。另一种选择是使用动态标量，但基本上动态标量可以完成下面的错误代码。我没有看到太多的改进，而其他人在使用动态标量时总是说（总）不好。

我仍在阅读perl开始，所以不知道还有哪些其他选项可用。任何帮助将不胜感激。

my @genotype1 = split (/:/, $original_line[6]); 
my @genotype2 = split (/:/, $original_line[7]); 
my @genotype3 = split (/:/, $original_line[8]); 
my @genotype4 = split (/:/, $original_line[9]); 
my @genotype5 = split (/:/, $original_line[10]); 
my @genotype6 = split (/:/, $original_line[11]); 
my @genotype7 = split (/:/, $original_line[12]); 
my @genotype8 = split (/:/, $original_line[13]); 
my @genotype9 = split (/:/, $original_line[14]); 
my @trio1 = ($genotype1[0], $genotype2[0], $genotype3[0]); 
my @trio2 = ($genotype4[0], $genotype5[0], $genotype6[0]); 
my @trio3 = ($genotype7[0], $genotype8[0], $genotype9[0]);

来源

2013-04-21 B Chen

什么是动态标量？在stackoverflow上搜索“动态标量”会产生另外两个问题，它们都不涉及Perl。 – mob 2013-04-21 00:17:51

@mob：我*想*他可能意味着符号引用，但这几乎只是一个猜测。 – jwodder 2013-04-21 00:21:42

如果您使用的 “动态变量”，你将有

for (6..14) { 
    @{ "genotype".($i-6) } = split (/:/, $original_line[$i]); 
}

它只是改变

my @genotypes; 
for (6..14) { 
    @{ $genotypes[$i-6] } = split (/:/, $original_line[$i]); 
}

这可能是有点清洁器

my @genotypes; 
for (6..14) { 
    $genotypes[$i-6] = [ split (/:/, $original_line[$i]) ]; 
}

或

my @genotypes; 
for (6..14) { 
    push @genotypes, [ split (/:/, $original_line[$i]) ]; 
}

或

my @genotypes; 
for (@original_line[6..14]) { 
    push @genotypes, [ split /:/ ]; 
}

或

my @genotypes = map { [ split /:/ ] } @original_line[6..14];

但是，你只需要在第一个元素，所以你可以使用

my @genotypes = map { (split /:/)[0] } @original_line[6..14];

然后，你需要的是抢来自该阵列的三个元素一次，所以你得到：

my @genotypes = map { (split /:/)[0] } @original_line[6..14]; 

my @trioes; 
while (@genotypes) { 
    push @trios, [ splice @genotypes, 0, 3 ]; 
}

来源

2013-04-21 00:32:24 ikegami

有几种不同的方法可以使您的代码更高效;大多数（所有？）都会利用这样一个事实，即您只使用每个@genotype列表的第一个元素。举个例子：

my @elements = map { (split /:/)[0] } @original_line[6..14]; 
my @trio1 = @elements[0,1,2]; 
my @trio2 = @elements[3,4,5]; 
my @trio3 = @elements[6,7,8];

来源

2013-04-21 00:21:10 jwodder

如何正确使用数组，而不是使用动态标量变量

回答

相关问题