VBA：自定义数据类型和函数（返回值）

Question

在测试以下内容时，我在最后一行出现编译错误：（只有在公共对象模块中定义的公共用户定义类型可以强制到变体或从变体或传递到后期绑定功能。）

---

Option Explicit 

Public Type aType 
    P_Col As Integer 
    P_Rad As Single 
    P_X As Single 
    P_Y As Single 
End Type 


Function MakePatterns() As Variant 
Dim i As Integer 
Dim circles() As aType 

For i = 1 To 5 
    ReDim Preserve circles(i) 
    circles(i).P_Col = Int(i/2) 
    circles(i).P_Rad = i 
    circles(i).P_X = i * 10 + 1 
    circles(i).P_Y = i * 10 + 5 

Next 

For i = 1 To 5 
    Debug.Print circles(i).P_Col; circles(i).P_Rad; _ 
    circles(i).P_X; circles(i).P_Y 
Next 
MakePatterns = circles 

End Function 

---

是否有使用类型和功能一起返回数组的方法吗？还是有更有效的方法？

Answer 1

在下面子“TestCallFunction”调用功能“MakePatterns”，和它打印后立即窗口接收到的第一阵列从功能回来的代码。

Option Explicit 

Public Type aType 
    P_Col As Integer 
    P_Rad As Single 
    P_X As Single 
    P_Y As Single 
End Type 


Sub TestCallFunction() 

Dim x()     As aType 
Dim i     As Integer 

x = MakePatterns 

' print the first result received from Function MakePatterns 
Debug.Print x(1).P_Col & ";" & x(1).P_Rad & ";" & x(1).P_X & ";" & x(1).P_Y 

End Sub 

Public Function MakePatterns() As aType() 

Dim i     As Integer 
Dim circles()   As aType 

For i = 1 To 5 
    ReDim Preserve circles(i) 
    circles(i).P_Col = Int(i/2) 
    circles(i).P_Rad = i 
    circles(i).P_X = i * 10 + 1 
    circles(i).P_Y = i * 10 + 5 
Next 

For i = 1 To 5 
    Debug.Print circles(i).P_Col; circles(i).P_Rad; _ 
    circles(i).P_X; circles(i).P_Y 
Next 

MakePatterns = circles 

End Function