PHP ColdFusion9 AES加密 - 不同的结果

Question

PHP和ColdFusion9中的AES加密产生不同的结果。有人可以帮我吗？

的下面PHP代码

$key = "12345678123456781234567812345678"; 
$iv = "1234567812345678"; 
$data = "This is a plain string."; 

echo base64_encode(mcrypt_encrypt(MCRYPT_RIJNDAEL_128, $key, $data, MCRYPT_MODE_CBC, $iv)); 

给我G + tdEOfQTtVCQGxW3N5uzkqN207OyfIPxS6zf2xrKKY =

虽然下面ColdFusion代码

<cfset thePlainData = "This is a plain string." /> 
<cfset theKey = "12345678123456781234567812345678" /> 
<cfset theAlgorithm = "AES/CBC/PKCS5Padding" /> 
<cfset theEncoding = "base64" /> 
<cfset theIV = "1234567812345678" /> 

<cfset encryptedString = encrypt(thePlainData, theKey, theAlgorithm, theEncoding, theIV) /> 

给我KLt55n5/T3ee6xVq9VGFbyCacJznkHEqC/RDRhL + 4NW =

任何想法，我错了吗？提前致谢。

Answer 1

不幸的是，ColdFusion和PHP实现之间在使用明文填充风格方面存在轻微的不兼容性。 AES需要一个可被128整除的明文块大小。要达到此目的，可使用PHP will pad the plaintext input with NULL characters来获得适当的块大小。 ColdFusion可以使用各种padding techniques that are supported by Java。不幸的是，ColdFusion和Java都支持NULL填充模式，这使得互操作性变得更加困难。 ColdFusion的字符串处理不支持NULL字符，所以您需要implement a PKCS5Padding schema within PHP来代替它们以正确地进行交互操作。

此外，如在评论中提到的，ColdFusion的将期望键进行base64编码，所以你需要的关键的设置看起来像：

<cfset theKey = toBase64("12345678123456781234567812345678") /> 

此外，Java的默认（和ColdFusion由扩展名）只支持高达128位的密钥。在这里，您使用的是一个256位密钥，它将require the Java Unlimited Strength extension（对于那些试图测试代码并获得非法密钥大小错误的人）。

产生的PHP代码如下所示：

// Function from http://us3.php.net/manual/en/ref.mcrypt.php#69782 
function pkcs5_pad ($text, $blocksize) 
{ 
    $pad = $blocksize - (strlen($text) % $blocksize); 
    return $text . str_repeat(chr($pad), $pad); 
} 

$key = "12345678123456781234567812345678"; 
$iv = "1234567812345678"; 
// Pad data with PKCS #5 to prevent PHP from using NULL padding. 
$data = pkcs5_pad("This is a plain string.", 16); 

echo base64_encode(mcrypt_encrypt(MCRYPT_RIJNDAEL_128, $key, $data, MCRYPT_MODE_CBC, $iv)); 

生成的ColdFusion代码的样子：

<cfset thePlainData = "This is a plain string." /> 
<cfset theKey = toBase64("12345678123456781234567812345678") /> 
<cfset theAlgorithm = "AES/CBC/PKCS5Padding" /> 
<cfset theEncoding = "base64" /> 
<cfset theIV = "1234567812345678" /> 

<cfset encryptedString = encrypt(thePlainData, theKey, theAlgorithm, theEncoding, theIV) /> 

<cfoutput>#encryptedString#</cfoutput> 

两个输出相同的base64编码字符串：

G+tdEOfQTtVCQGxW3N5uzlu0mGabRKNxuIdAXArQE80= 

Answer 2

我知道这是一个古老的线索，但最近出现了类似的问题。

虽然本地不支持，但事实证明有一种方法可以在CF中生成空填充。 This answer by Artjom B.同意在PHP中调整填充可能会更简单，但指出使用“NoPadding”方案可以实现将纯文本以0x00填充到algorithm's block size和的倍数的相同结果。

在CF中生成空字符有点棘手，但可以执行using URLDecode("%00")。由于encrypt（）始终将输入视为UTF-8编码，因此您还可以使用charsetEncode（）从单个元素字节数组创建空字符，即charsetEncode(javacast("byte[]", [0]), "utf-8")。

不严格测试，但这样的事情应该产生CF10相同的结果：

代码：

thePlainData = nullPad("This is a plain string.", 16); 
// NB: JCE unlimited policy files required for 256 bit keys 
theKey = toBase64("12345678123456781234567812345678"); 
theIV = "1234567812345678"; 

encryptedString = encrypt(thePlainData, theKey, "AES/CBC/NoPadding", "base64", theIV); 

结果：

G+tdEOfQTtVCQGxW3N5uzkqN207OyfIPxS6zf2xrKKY= 

功能：

/* 
    Pads a string, with null bytes, to a multiple of the given block size 

    @param plainText - string to pad 
    @param blockSize - pad string so it is a multiple of this size 
    @param encoding - charset encoding of text 
*/ 
string function nullPad(string plainText, numeric blockSize, string encoding="UTF-8") 
{ 
    local.newText = arguments.plainText; 
    local.bytes = charsetDecode(arguments.plainText, arguments.encoding); 
    local.remain = arrayLen(local.bytes) % arguments.blockSize; 

    if (local.remain neq 0) 
    { 
     local.padSize = arguments.blockSize - local.remain; 
     local.newText &= repeatString(urlDecode("%00"), local.padSize); 
    } 

    return local.newText; 
}