如何将值从闪存传递到php

Question

你好，我是新来的闪光灯。正是我要如何从Flash变量值传递到PHP 我使用这个代码

var myVars:LoadVars = new LoadVars(); 
myVars.playerName = "Some Body"; 
myVars.playerTime = Timer; 

myVars.send("index.html", "_parent", "POST");` 

它显示错误 - >

警告：1060：迁移问题：方法的LoadVars不再支持的。欲了解更多信息，请参阅URLVariables类中，URLRequest.urlVariables和URLRequest.postData属性，URLLoader.dataFormat属性..

请指导我如何解决这个错误。我正在使用CS4的闪存和AS3.0

Answer 1

LoadVars()是仅AS2。您需要使用URLLoader。试试这个类：

package 
{ 
    import flash.net.URLRequest; 
    import flash.net.URLLoader; 
    import flash.net.URLVariables; 
    import flash.net.URLRequestMethod; 
    import flash.events.Event; 

    /** 
    * @author Marty Wallace 
    * @version 1.00 
    */ 
    public class PHPData extends Object 
    { 
     /** 
     * Sends data to a PHP script 
     * @param script A URL to the PHP script 
     */ 
     public function send(script:String, vars:URLVariables):void 
     { 
      var req:URLRequest = new URLRequest(script); 

      req.data = vars; 
      req.method = URLRequestMethod.POST; 

      var loader:URLLoader = new URLLoader(); 
      loader.load(req); 

      // listeners 
      loader.addEventListener(Event.COMPLETE, _complete); 
     } 

     /** 
     * Called when a response has been received from a PHP script 
     * @param e Event.COMPLETE 
     */ 
     private function _complete(e:Event):void 
     { 
      var vars:URLVariables = new URLVariables(e.target.data); 

      var i:String; 
      for(i in vars) 
      { 
       trace(i + ": " + vars[i]); 
      } 

      e.target.removeEventListener(Event.COMPLETE, _complete); 
     } 
    } 
} 

然后，你可以做你在做什么，像这样：

var php:PHPData = new PHPData(); 
var vars:URLVariables = new URLVariables(); 

vars.playerName = "Some Body"; 
vars.playerTime = Timer; 

php.send("index.php", vars); 

另一件事我注意到你正在使用发送到数据发送到的.html文件而不是.PHP文件..

---

上创建该类使用小教程（基于评论）：

1. 单击文件 - >新建 - > ActionScript文件。
2. 将上面的包（第一块代码）粘贴到新文件中。
3. 将文件保存为同一目录作为.fla文件。
4. 将我的第二段代码粘贴到.fla文件的时间轴中。

所有应该从这里工作。

---

这是一个包含您可以使用的示例的.zip。

http://junk.projectavian.com?f=phpdata.zip