如何从当前表单打开另一个表单？

Question

我们的第一种形式是登录表单..如何在登录后打开下一个表单？

Answer 1

在您的登录表单中，我假设您在按钮控件的Click事件方法内执行验证。所以，你会碰到这样的：这个代码的

Private Sub btnLogin_Click() 
    If ValidatePassword(txtPassword.Text) Then 
     ' The password is correct, so show the main form and close the login form 
     MainForm.Show 
     Unload Me 
    Else 
     ' The password is incorrect, so leave this form on screen 
     MsgBox "Invalid password entered!", vbError 
     txtPassword.SetFocus 
    End If 
End Sub 

两个有趣的特点是：

1. 的Show方法，你要显示窗体对象调用。
   在这种情况下，它可能会成为您的主要形式 - 用所谓的任何东西代替MainForm。

2. Unload声明，它关闭并销毁指定的表单。
   在这种情况下，Me指的是登录表单，因为您完成了它。

Answer 2

您需要拨打电话Show，需要在登录表单后显示。你可以阅读更多关于Understanding Forms and form events

Answer 3

我的方法是避免尝试打开登录窗体作为第一个窗体。

取而代之让主窗体成为第一个，并在其Load事件中将您的登录窗体显示为模态对话框。这可以通过对其进行显示来首先显示主窗体。基于标准模板 “登录对话框的” 形式与一些代码的变化举例：

frmMain.frm

Option Explicit 

Private Sub Form_Load() 
    Dim Control As Control 

    Show 
    frmLogin.Show vbModal, Me 
    With frmLogin 
     txtSuccess.Text = CStr(.LoginSucceeded) 
     If .LoginSucceeded Then 
      'Proceed normally, perhaps after capturing 
      'the User Name, etc. 
      txtUserName.Text = .User 
      txtPassword.Text = .Password 
     Else 
      'Do "Unload Me" or disable all controls 
      'as shown here, etc. 
      For Each Control In Controls 
       On Error Resume Next 
       Control.Enabled = False 
       On Error GoTo 0 
      Next 
     End If 
    End With 
    Unload frmLogin 
End Sub 

frmLogin.frm

Option Explicit 

Public LoginSucceeded As Boolean 
Public User As String 
Public Password As String 

Private Sub cmdCancel_Click() 
    LoginSucceeded = False 
    Hide 
End Sub 

Private Sub cmdOK_Click() 
    'Check for correct password, hard-coded here. 
    If txtPassword.Text = "password" Then 
     LoginSucceeded = True 
     User = txtUserName.Text 
     Password = txtPassword.Text 
     Hide 
    Else 
     MsgBox "Invalid Password, try again!", , "Login" 
     With txtPassword 
      .SetFocus 
      .SelStart = 0 
      .SelLength = Len(.Text) 
     End With 
    End If 
End Sub