使用xml-to-json。 “内部XML/XHTML” 应该在JSON字符串值字段

Question

我使用撒克逊家庭版，以XML转换成JSON：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" encoding="UTF-8" /> 
    <xsl:template match="/"> 
     <xsl:variable name="xmljson"> 
      <map xmlns="http://www.w3.org/2005/xpath-functions"> 
       <string key="name">Some name</string> 
       <string key="description">A nice description</string> 
      </map> 
     </xsl:variable> 
     <xsl:value-of select="xml-to-json($xmljson)" /> 
    </xsl:template> 
</xsl:stylesheet> 

产生所需的输出：

{"name":"Some name","description":"A nice description"} 

说明字段包含任意复杂的xhtml。

<string key="description">A <strong>nice</strong> description</string> 

错误消息：模板规则不与下面的描述领域的工作

xml-to-json: unknown element <strong> 

括在CDATA节的描述不工作：

<string key="description"><![CDATA[A <strong>nice</strong> description]]></string> 

所需的输出：

{"name":"Some name","description":"A <strong>nice<\/strong> description"} 

问题

说明字段的内容是变换的结果。所以，随着CDATA的失败。 这样可不行：

<string key="description"><xsl:apply-template select="description" /></string> 

无论是这样的：

<string key="description"><![CDATA[<xsl:apply-template select="description" />]]></string> 

Answer 1

使用serialize() function产生逃脱的XML标记为文本。

<xsl:variable name="options" as="element()"> 
    <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization"> 
    <output:omit-xml-declaration value="yes"/> 
    </output:serialization-parameters> 
</xsl:variable> 

<xsl:variable name="xmljson" as="element()"> 
    <map xmlns="http://www.w3.org/2005/xpath-functions"> 
    <string key="name">Some name</string> 
    <string key="description"><xsl:value-of select="serialize(description, $options)"/></string> 
    </map> 
</xsl:variable> 

Answer 2

我想出了以下快速入门。必须再次检查这个明天，现在有点累......牛逼

---

编辑：这是一个可怕的黑客！模板规则不处理特殊字符。请阅读下面的评论。

---

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" encoding="UTF-8" /> 

    <xsl:template match="/"> 
     <xsl:variable name="doc"> 
      <description>A <strong class="red">nice</strong> description</description> 
     </xsl:variable> 
     <xsl:variable name="xmljson"> 
      <map xmlns="http://www.w3.org/2005/xpath-functions"> 
       <string key="description"><xsl:apply-templates select="$doc/description/text()|$doc/description/*" /></string> 
      </map> 
     </xsl:variable> 
     <xsl:value-of select="xml-to-json($xmljson)" /> 
    </xsl:template> 

    <xsl:template match="*"> 
     <!-- opening tag --> 
     <xsl:text>&lt;</xsl:text> 
     <xsl:value-of select="name()"/> 
     <!-- attribute nodes --> 
     <xsl:apply-templates select="@*"/> 
     <xsl:text>&gt;</xsl:text> 
     <xsl:apply-templates/> 
     <!-- closing tag --> 
     <xsl:text>&lt;</xsl:text> 
     <xsl:text>/</xsl:text> 
     <xsl:value-of select="name()"/> 
     <xsl:text>&gt;</xsl:text> 
    </xsl:template> 

    <xsl:template match="@*"> 
     <xsl:text> </xsl:text> 
     <xsl:value-of select="name()"/> 
     <xsl:text>="</xsl:text> 
     <xsl:value-of select="." /> 
     <xsl:text>"</xsl:text> 
    </xsl:template> 

</xsl:stylesheet> 

产生所需的输出：

{"description":"A <strong class=\"red\">nice<\/strong> description"}