无法获得正确的XSLT输出

我有这样的XML：无法获得正确的XSLT输出

<Section> 
    <Chapter> 
     <Head>Heading</Head> 
     <nametable> 
      <nametitle>MyTitle</nametitle> 
      <namedomain>MyDomain</namedomain> 
      <namevalue>value1</namevalue> 
     </nametable> 
     <nametable> 
      <nametitle>MyTitle2</nametitle> 
      <namedomain>MyDomain2</namedomain> 
      <namevalue>value2</namevalue> 
     </nametable> 
    </Chapter> 
</Section>

我希望得到如下的输出：

MyTitle2 
MyDomain2 
value2

我用text()功能检查的文本内容但它不打印任何东西。

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:fo="http://www.w3.org/1999/XSL/Format"> 

<xsl:template match="//Chapter"> 
    <xsl:comment>Ignore Head tag</xsl:comment> 
    <xsl:apply-templates select="*[not(self::Head)]"/> 
</xsl:template> 

<xsl:template match="nametable"> 
    <xsl:for-each select="nametitle"> 
     <xsl:if test="text()='MyTitle2'"> 
      <xsl:apply-templates select="nametitle" /> 
     </xsl:if> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template match="nametitle"> 
    <xsl:apply-templates /> 
</xsl:template> 

</xsl:stylesheet>

我做错了什么？

谢谢！

约翰

来源

2012-02-21 JohnX

你的问题是在这里：

<xsl:for-each select="nametitle"> 
    <xsl:if test="text()='MyTitle2'"> 
     <xsl:apply-templates select="nametitle" /> 
    </xsl:if> 
</xsl:for-each>

如果测试成功，则模板将被应用到nametitle孩子当前的节点。

但是，当前节点是nametitle，它没有nametitle子 - 因此没有选择节点，也没有应用模板。

解决方案：

这种转变：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:output method="text"/> 

<xsl:template match="nametable[nametitle = 'MyTitle2']/*"> 
    <xsl:value-of select="."/> 
    <xsl:text>&#xA;</xsl:text> 
</xsl:template> 

<xsl:template match="text()"/> 
</xsl:stylesheet>

时所提供的XML文档应用：

<Section> 
    <Chapter> 
     <Head>Heading</Head> 
     <nametable> 
      <nametitle>MyTitle</nametitle> 
      <namedomain>MyDomain</namedomain> 
      <namevalue>value1</namevalue> 
     </nametable> 
     <nametable> 
      <nametitle>MyTitle2</nametitle> 
      <namedomain>MyDomain2</namedomain> 
      <namevalue>value2</namevalue> 
     </nametable> 
    </Chapter> 
</Section>

产生想要的，正确的结果：

 MyTitle2 
     MyDomain2 
     value2

来源

2012-02-21 04:25:42

谢谢，我感谢您的帮助！ – JohnX 2012-02-21 22:11:49

@JohnX：我很高兴我的回答对你有用。请考虑接受这个答案（提示：点击答案旁边的复选标记）。 – 2012-02-21 22:15:57

我有一个问题，如果我用''替换''并为nametitle提供模板匹配（包含）您的解决方案将打印MyTitle而不是MyTitle2。我想知道为什么这是因为支票是MyTitle2。 – JohnX 2012-02-22 16:56:30

两种替代产生相同的结果：

<xsl:template match="nametitle[text()='MyTitle2']"> 
<xsl:value-of select="parent::node()"/> 
<xsl:text>&#xA;</xsl:text> 
</xsl:template>

和

<xsl:template match="*[nametitle[text()='MyTitle2']]"> 
<xsl:value-of select="."/> 
<xsl:text>&#xA;</xsl:text> 
</xsl:template>

来源

2012-02-21 06:32:48

谢谢，我感谢您的帮助！ – JohnX 2012-02-21 22:12:13

无法获得正确的XSLT输出

回答

相关问题