从nexus快照仓库更新gradle更换模块没有更新

Question

我没有上传快照工件时出现问题。

我正在使用快照版本。 Atrifact被明确标记为changing: true，并且cacheChangingModulesFor被设置为0秒。

当我运行--refresh-dependecies工件被正确地重新下载。

我在使用gradle 2.9的时候发现了这个问题。但升级到2.14.1后，问题依然存在。

下面是我的build.gradle文件：

buildscript { 
    ext { 
     springBootVersion = '1.3.5.RELEASE' 
    } 
    repositories { 
     mavenCentral() 
     maven { url 'http://repo.spring.io/plugins-release' } 
    } 
    // dependencies for plugins 
    dependencies { 
     classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}" 
     classpath 'org.springframework.build.gradle:propdeps-plugin:0.0.7' 
    } 
} 


apply plugin: 'java' 
apply plugin: 'idea' 
apply plugin: 'spring-boot' 
apply plugin: 'war' 
apply plugin: 'propdeps' 
apply plugin: 'propdeps-maven' 
apply plugin: 'propdeps-idea' 

configurations.all { 
    // Check for updates every build 
    resolutionStrategy.cacheChangingModulesFor 0, 'seconds' 
} 


jar { 
    baseName = 'someproject' 
    version = '0.0.1-SNAPSHOT' 
} 

war { 
    baseName = "someproject" 
    version = '0.0.1-SNAPSHOT' 
} 

sourceCompatibility = 1.8 
targetCompatibility = 1.8 

repositories { 
    mavenCentral() 
    maven { url "https://jitpack.io" } 
    maven { 
     url 'http://nexus.example.com:8081/nexus/content/repositories/java-libs-snapshots/' 
     credentials { 
      username "someuser" 
      password "somepassword" 
     } 
    } 
} 

// enables to run with dev profile: $ gradle local bootRun 
task local << { 
    bootRun.systemProperty 'spring.profiles.active', 'local' 
} 

bootRun { 
    jvmArgs = ["-agentlib:jdwp=transport=dt_socket,server=y,suspend=n,address=5005"] 
} 

dependencies { 
    compile 'mysql:mysql-connector-java' 
    compile 'org.springframework.boot:spring-boot-starter-web' 
    compile group: "pl.example", name: "name", version: "0.7.6.1-SNAPSHOT", changing: true 
    compile 'org.jadira.usertype:usertype.core:5.0.0.GA' 
    compile group: 'com.rometools', name: 'rome', version: '1.6.0' 
    compile group: 'org.jsoup', name: 'jsoup', version: '1.9.2' 
    compile 'org.hibernate:hibernate-search:5.5.3.Final' 
    compile 'org.projectlombok:lombok:1.16.6' 
} 

Answer 1

我想你也许有变化的相关性稍有不当的语法。

你可以尝试更换：

compile group: "pl.example", name: "name", version: "0.7.6.1-SNAPSHOT", changing: true 

有：

compile ("pl.example:name:0.7.6.1-SNAPSHOT"){ changing = true } 

你能不能也尝试加入一行到resolutionStrategy为cacheDynamicVersionsFor如下：

configurations.all {  
    resolutionStrategy { 
     cacheDynamicVersionsFor 0, "seconds" 
     cacheChangingModulesFor 0, "seconds" 
    } 
}