如何使任意SAS格式的字符变量等于数值变量的格式化值？

Question

如果我有一个格式的数值变量，有没有办法将格式化的值作为字符变量？

例如我想写下如下内容来将10/06/2009打印到屏幕上，但没有putformatted()功能。

data test; 
    format i ddmmyy10.; 
    i = "10JUN2009"d; 
run; 

data _null_; 
    set test; 
    i_formatted = putformatted(i); /* How should I write this? */ 
    put i_formatted; 
run; 

（很明显，我可以写put(i, ddmmyy10.)，但我的代码需要为任何格式i恰巧有工作）。

Answer 1

的VVALUE函数格式使用变量相关的格式传递给它的变量。下面是使用VVALUE代码：

data test; 
    format i ddmmyy10.; 
    i = "10JUN2009"d; 
run; 

data _null_; 
    set test; 
    i_formatted = vvalue(i); 
    put i_formatted; 
run; 

虽然cmjohns解决方案是略快于这个代码，这个代码更简单，因为没有涉及到宏。

Answer 2

我能做到这一点与宏代码和sashelp.vcolumn，但它是一个有点繁琐。

proc sql noprint; 
    select trim(left(format)) into :format 
    from sashelp.vcolumn 
    where libname eq 'WORK' and memname eq 'TEST'; 
run; 

data test2; 
    set test; 
    i_formatted = put(i, &format); 
    put i_formatted; 
run; 

Answer 3

这似乎适用于我试过的一对夫妇。我使用了VARFMT和一个宏函数来检索给定变量的格式。

data test; 
    format i ddmmyy10. b comma12.; 
    i = "10JUN2009"d; 
    b = 123405321; 
run; 


%macro varlabel(variable) ; 
    %let dsid=%sysfunc(open(&SYSLAST.)) ; 
    %let varnum=%sysfunc(varnum(&dsid,&variable)) ; 
    %let fmt=%sysfunc(varfmt(&dsid,&varnum)); 
    %let dsid=%sysfunc(close(&dsid)) ; 
    &fmt 
%mend varlabel; 

data test2; 
    set test; 
    i_formatted = put(i, %varlabel(i)); 
    b_formatted = put(b, %varlabel(b)); 
    put i_formatted=; 
    put b_formatted=; 
run; 

这给了我：

i_formatted=10/06/2009 
b_formatted=123,405,321 

Answer 4

使用vformat()功能。

/* test data */ 
data test; 
    i = "10jun2009"d; 
    format i ddmmyy10.; 
run; 

/* print out the value using the associated format */ 
data _null_; 
    set test; 
    i_formatted = putn(i, vformat(i)); 
    put i_formatted=; 
run; 
/* on log 
i_formatted=10/06/2099 
*/ 

Answer 5

是的，有一个putformatted（）函数。实际上，有两个：putc（）和putn（）。 Putc处理字符格式，putn（）数字。您的代码需要查看格式名称（所有字符格式和唯一字符格式均以“$”开头）确定要使用哪种格式。这里是putc将语法（从交互式的帮助）：

PUTC(source, format.<,w>) 

参数

source 
is the SAS expression to which you want to apply the format. 

format. 
is an expression that contains the character format you want to apply to source. 

w 
specifies a width to apply to the format. 

Interaction: If you specify a width here, it overrides any width specification 
in the format.