EXCEL VBA如何使用函数和分割从字符串中提取整数

Question

我正在处理一段代码以从其标记名中提取管道的标称大小。例如：L-P-50-00XX-0000-000。 。50将是它的标称尺寸（2" ），我想提取我知道我能做到这一点是这样的：

TagnameArray() = Split("L-P-50-00XX-0000-000", "-") 
DNSize = TagnameArray(2) 

但我想这是一个功能，因为它是一小部分我整个宏观，我并不需要它为所有我的工作只是这一个植物我当前的代码是：

Sub WBDA_XXX() 
Dim a As Range, b As Range 
Dim TagnameArray() As String 
Dim DNMaat As String 
Dim DN As String 

Set a = Selection 

For Each b In a.Rows 
    IntRow = b.Row 
    TagnameArray() = Split(Cells(IntRow, 2).Value, "-") 
    DN = DNMaat(IntRow, TagnameArray()) 
    Cells(IntRow, 3).Value = DN 
Next b 
End Sub 



Function DNMaat(IntRow As Integer, TagnameArray() As String) As Integer 
    For i = LBound(TagnameArray()) To UBound(TagnameArray()) 
     If IsNumeric(TagnameArray(i)) = True Then 
      DNMaat = TagnameArray(i) 
      Exit For 
     End If 
    Next i 
End Function 

但是这个代码给了我一个矩阵预期的错误，我不知道如何我还想在进一步的计算中使用名义大小，所以在从标记名中提取它之后，必须将它转换为整数。有没有人看到我在代码中犯了错误？

Answer 1

这很容易做到分裂，并从'喜欢'评估一点帮助。

上“喜欢”一点背景 - 将基于输入变量是否一个给定的模式匹配返回TRUE或FALSE。 [A-Z]表示它可以是A和Z之间的任何大写字母，而#表示任意数字。

代码：

' Function declared to return variant strictly for returning a Null string or a Long 
Public Function PipeSize(ByVal TagName As String) As Variant 
    ' If TagName doesn't meet the tag formatting requirements, return a null string 
    If Not TagName Like "[A-Z]-[A-Z]-##-##[A-Z]-####-###" Then 
     PipeSize = vbNullString 
     Exit Function 
    End If 

    ' This will hold our split pipecodes 
    Dim PipeCodes As Variant 
    PipeCodes = Split(TagName, "-") 

    ' Return the code in position 2 (Split returns a 0 based array by default) 
    PipeSize = PipeCodes(2) 
End Function 

您将要考虑改变根据您的需求函数的返回类型。如果输入标签不匹配模式，它将返回一个空字符串，否则返回一个长（数字）。如果需要，您可以将其更改为返回字符串，或者您可以编写第二个函数来将该数字解释为长度。

下面是您的代码的重构版本，它只查找第一个数字标记。我清理了一下你的代码，我想我也发现了这个bug。你被宣布DNMAAT为String，但也要求它作为一个Function。这可能会导致您的阵列预期错误。

下面的代码：

' Don't use underscores '_' in names. These hold special value in VBA. 
Sub WBDAXXX() 
    Dim a As Range, b As Range 
    Dim IntRow As Long 

    Set a = Selection 

    For Each b In a.Rows 
     IntRow = b.Row 
     ' No need to a middleman here. I directly pass the split values 
     ' since the middleman was only used for the function. Same goes for cutting DN. 
     ' Also, be sure to qualify these 'Cells' ranges. Relying on implicit 
     ' Activesheet is dangerous and unpredictable. 
     Cells(IntRow, 3).value = DNMaat(Split(Cells(IntRow, 2).value, "-")) 

    Next b 
End Sub 

' By telling the function to expect a normal variant, we can input any 
' value we like. This can be dangerous if you dont anticipate the errors 
' caused by Variants. Thus, I check for Arrayness on the first line and 
' exit the function if an input value will cause an issue. 
Function DNMaat(TagnameArray As Variant) As Long 
    If Not IsArray(TagnameArray) Then Exit Function 

    Dim i As Long 
    For i = LBound(TagnameArray) To UBound(TagnameArray) 
     If IsNumeric(TagnameArray(i)) = True Then 
      DNMaat = TagnameArray(i) 
      Exit Function 
     End If 
    Next i 
End Function 

Answer 2

错误matrix expected由编译器抛出，因为你已经定义DNMaat两次：作为一个功能一旦作为字符串变量和一次。将定义作为变量移除。

另一件事：你的函数会返回一个整数，但是你把它分配给一个字符串（这个字符串用来只是把结果写入到一个细胞）。摆脱可变DN，并直接分配给它：

Cells(IntRow, 3).Value = DNMaat(IntRow, TagnameArray()) 

加上全球建议使用option explicit强制所有使用的变量的定义，定义一个变量总是抱着一个行/列数long而不是integer