您可以在类型约束参数上设置匹配构造函数吗？

Question

请参阅下面的代码示例。它不会编译。我曾想过也许是因为它必须为测试函数中的第一个参数设置一个类型。但这是没有道理的，因为如果我没有模式匹配，所以它会编译，我可以称它为MyObj11 5和MyObj21 5这是两种不同的类型。

那么这是什么限制，所以你不能在类型约束参数的构造函数上模式匹配？还是有一些你可以的机制？

class SomeClass a where toString :: a -> String 

instance SomeClass MyType1 where toString v = "MyType1" 
instance SomeClass MyType2 where toString v = "MyType2" 

data MyType1 = MyObj11 Int | MyObj12 Int Int 
data MyType2 = MyObj21 Int | MyObj22 Int Int 

test :: SomeClass a => a -> String 
test (MyObj11 x) = "11" 
test (MyObj12 x y) = "12" -- Error here if remove 3rd line: rigid type bound error 
test (MyObj22 x y) = "22" -- Error here about not match MyType1. 

Answer 1

它是什么，一个类型的类约束参数限制在构造函数，所以你不能模式匹配？

当您在显式构造函数上进行模式匹配时，您将提交给特定的数据类型表示。这种数据类型不是在类的所有实例之间共享的，所以不可能用这种方式编写适用于所有实例的函数。

相反，你需要不同的行为，你想与每个实例相关联，就像这样：现在

class C a where 
    toString :: a -> String 
    draw  :: a -> String 

instance C MyType1 where 
    toString v = "MyType1" 

    draw (MyObj11 x) = "11" 
    draw (MyObj12 x y) = "12" 

instance C MyType2 where 
    toString v = "MyType2" 

    draw (MyObj22 x y) = "22" 

data MyType1 = MyObj11 Int | MyObj12 Int Int 
data MyType2 = MyObj21 Int | MyObj22 Int Int 

test :: C a => a -> String 
test x = draw x 

你原来test功能的分支机构分布在实例之中。

一些替代技巧涉及使用class-associated data types（向编译器证明数据类型在所有实例之间共享）或view patterns（它允许您概括模式匹配）。

---

查看模式

我们可以使用视图模式来清理模式匹配和类型的类的实例，有点之间的连接，让我们通过模式上的共享匹配近似的图案跨实例匹配类型。

下面是一个例子，我们写了一个函数，有两种情况，让我们对类中的任何事物进行模式匹配。

{-# LANGUAGE ViewPatterns #-} 

class C a where 
    view  :: a -> View 

data View = One Int 
      | Two Int Int 

data MyType1 = MyObj11 Int | MyObj12 Int Int 

instance C MyType1 where 
    view (MyObj11 n) = One n 
    view (MyObj12 n m) = Two n m 

data MyType2 = MyObj21 Int | MyObj22 Int Int 

instance C MyType2 where 
    view (MyObj21 n) = One n 
    view (MyObj22 n m) = Two n m 

test :: C a => a -> String 
test (view -> One n) = "One " ++ show n 
test (view -> Two n m) = "Two " ++ show n ++ show m 

注意->语法如何让我们在每一个实例回调到合适的view功能，查找每类自定义数据类型的编码，以模式匹配就可以了。

设计的挑战是要拿出捕获所有的行为变种你感兴趣的视图类型。

在你原来的问题，你想每一个构造有不同的行为，所以实际上没有使用视图类型的原因（在每个实例中直接调度到该行为已经足够好）。