如何在grails中将文件上传到远程FTP服务器

Question

我是Grails框架的新手。我需要通过Grails中的批量应用程序将文本文件上传到远程FTP服务器。如果有人有任何建议，一步一步的过程请求如何连接到远程服务器并上传文件。

在此先感谢。

Answer 1

首先，在您的BuildConfig.groovy（Grails的2.X）公网或的build.gradle（Grails的3.X）：

compile 'commons-net:commons-net:3.3'

其次添加服务：

class UploadService { 
    GrailsApplication grailsApplication 

    String upload(String fileName, InputStream inputStream) { 
     String status 
     new FTPClient().with { 
      connect grailsApplication.config.getProperty('ftp.host') 
      login grailsApplication.config.getProperty('ftp.username'), grailsApplication.config.getProperty('ftp.password') 
      enterLocalPassiveMode() 
      setFileType(BINARY_FILE_TYPE) 
      changeWorkingDirectory grailsApplication.config.getProperty('ftp.uploadDir') 
      storeFile(fileName, inputStream) 
      status = replyString 
      disconnect() 
     } 
     return status 
    } 
} 

更新：

我忘了补充一点，需要进入grails-app/conf/Config.groovy（Grails的2.X）或grails-app/config/application.groovy配置：

ftp { 
    host = 'some.host' 
    username = 'myuser' 
    password = '*****' 
    uploadDir = 'Uploads' 
} 

这也将是可能的resources.groovy创建FTPClient（）实例，并使用依赖注入代替。

bean = { 
    ftpClient(FTPClient) 
} 

，然后让这个在服务：

class UploadService { 
    GrailsApplication grailsApplication 
    FTPClient ftpClient // Will be injected 

    String upload(String fileName, InputStream inputStream) { 

     String status 
     ftpClient.with { 
       // Same as above 
     } 
    } 
} 

这将让你单元测试类，在那里你只需模拟出FTPClient