照片加载顺序乱了as3

Question

我已经创建了一个容器（或影片剪辑），将按顺序添加照片并显示在舞台上。但是，由于文件大小不同，它会首先添加最小的文件大小照片。我怎么能解决这个问题。请参阅下面

// image0.jpg -> 3k 
// image1.jpg -> 2k 
// image2.jpg -> 1k 
// image3.jpg -> 2k 
// image5.jpg -> 1k 

var photoPath:Array = new Array(); 
var photoContainer:MovieClip = new MovieClip(); 

photoPath.push('image0.jpg'); 
photoPath.push('image1.jpg'); 
photoPath.push('image2.jpg'); 
photoPath.push('image3.jpg'); 
photoPath.push('image4.jpg'); 

for(var i = 0; i < photoPath.length; i++) 
{ 
    var loader:Loader = new Loader(); 
    loader.load(URLRequest(photoPath[i])); 
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, photoLoaded); 
} 

function photoLoaded(e:Event):void 
{ 
    photoContainer.addChild(e.target.content); 
} 

//output will looks like (image2,image5,image1,image3,image0) instead of 0,1,2,3,4,5 

Answer 1

示例代码中有相当多的方式来处理这个问题，可能是你改造现有的代码最简单的方法是，因为它被实例化的装载机添加到显示列表。这将确保它们以正确的顺序放入photoContainer中。如果你绝对需要的位图本身是在显示列表，而不是装载机本身，你可以在你的photoLoaded方法解决这个问题：

import flash.display.Loader; 

var photoPath:Array = new Array(); 
var photoContainer:MovieClip = new MovieClip(); 

photoPath.push('image0.jpg'); 
photoPath.push('image1.jpg'); 
photoPath.push('image2.jpg'); 
photoPath.push('image3.jpg'); 
photoPath.push('image4.jpg'); 

for(var i = 0; i < photoPath.length; i++) 
{ 
    var loader:Loader = new Loader(); 
    photoContainer.addChild(loader); //add the loader to photoContainer 
    loader.load(new URLRequest(photoPath[i])); 
    //you only actually have to listen for complete below if you want to replace the loader with its contents 
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, photoLoaded); 
} 

function photoLoaded(e:Event):void 
{ 
    var loader:Loader = e.target.loader; 
    var index:int = photoContainer.getChildIndex(loader); 
    // this will add the contents of the loader in the same order the loader was originally added 
    photoContainer.addChildAt(loader.content, index); 
    photoContainer.removeChild(loader); 
} 

Answer 2

简单的负载，并增加了照片的容器在给定的顺序阵列：

var photoPath:Array = new Array(); 
var photoContainer:MovieClip = new MovieClip(); 
var i:int = 0; 

photoPath.push('image0.jpg'); 
photoPath.push('image1.jpg'); 
photoPath.push('image2.jpg'); 
photoPath.push('image3.jpg'); 
photoPath.push('image4.jpg'); 

loadPhoto(i); 

function loadPhoto(i:int):void 
{ 
    var loader:Loader = new Loader(); 
    loader.load(new URLRequest(photoPath[i])); 
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, photoLoaded); 
} 

function photoLoaded(e:Event):void 
{ 
    photoContainer.addChild(e.target.content); 
    trace(e.target.url); // Verify 
    if(i<photoPath.length-1) loadPhoto(++i); 
} 

输出：

image0.jpg 
image1.jpg 
image2.jpg 
image3.jpg 
image4.jpg