在Word文档的第一页页脚中查找并替换

Question

我使用此宏替换不同文档中的某些值，但不替换第一页页脚中的文本。我想这是因为第一页页脚与其他页面不同。我刚开始使用VBA代码，所以我不知道如何解决这个问题。我会很感激，如果有人能够为我修改宏，以便它能够在第一页的页脚中查找和替换值？

Sub DoReplace() 

Const Find1 = "FIND TEXT" 
Const Replace1 = "REPLACE TEXT" 

Const Find2 = "FIND TEXT" 
Const Replace2 = "REPLACE TEXT" 

Dim FilePick As FileDialog 
Dim FileSelected As FileDialogSelectedItems 
Dim WordFile As Variant ' FileName placeholder in selected files loop 
Dim FileJob As String ' Filename for processing 

Dim WorkDoc As Object 
Dim WholeDoc As Range 
Dim FooterDoc As Range 

On Error GoTo DoReplace_Error 

    Set FilePick = Application.FileDialog(msoFileDialogFilePicker) 

    With FilePick 
     .Title = "Choose Report Template" 
     .Filters.Clear 
     .Filters.Add "Word Documents & Templates", "*.do*" 
     .Filters.Add "Word 2003 Document", "*.doc" 
     .Filters.Add "Word 2003 Template", "*.dot" 
     .Filters.Add "Word 2007 Document", "*.docx" 
     .Filters.Add "Word 2007 Template", "*.dotx" 
     .Show 
    End With 

    Set FileSelected = FilePick.SelectedItems 

    If FileSelected.Count <> 0 Then 

     For Each WordFile In FileSelected 

      FileJob = WordFile 

      Set WorkDoc = Application.Documents.Open(FileJob, , , , , , , , , , , False) 

      Set WholeDoc = WorkDoc.Content 
      Set FooterDoc = WorkDoc.Sections(1).Footers(wdHeaderFooterPrimary).Range 

      With FooterDoc 
       .Find.Execute Find1, True, True, , , , True, , , Replace1, wdReplaceAll 
       .Find.Execute Find2, True, True, , , , True, , , Replace2, wdReplaceAll 
      End With 

      With WholeDoc.Find 
       .Execute Find1, True, True, , , , True, , , Replace1, wdReplaceAll 
       .Execute Find2, True, True, , , , True, , , Replace2, wdReplaceAll 

      End With 

      WorkDoc.Save 
      WorkDoc.Close 

     Next 

    End If 

    MsgBox "Completed" 

DoReplace_Exit: 

    Set WholeDoc = Nothing 
    Set FilePick = Nothing 

    Set WorkDoc = Nothing 
    Set FooterDoc = Nothing 

    Exit Sub 

DoReplace_Error: 

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure DoReplace of VBA Document ReplaceMulti" 
    Resume DoReplace_Exit 

End Sub 

Answer 1

创建另一个变量并将其他页脚分配给它。像

Dim footerPage1 as Word.Range 
Set footerPage1 = WorkDoc.Sections(1).Footers(wdHeaderFooterFirstPage).Range 

东西但有一个更好的方式去在整个文档中搜索，而无需了解，并指定每个“故事”。首先查找物业的文档：StoryRanges

这包含将给你一个开始的示例代码。然后在互联网上按以下条款进行搜索以详细了解如何使用它：

Word find StoryRanges