我的平均功能是计数空白单元格为0

Question

据我所知，Excel平均函数不包括空白的单元格。不过，我这似乎正是我的代码是这样做的：

Sub sumavg() 
    Dim rowCounter As Long 
    Dim colCounter As Long 

    Dim values() As Variant 

    Const START_COL As Long = 1 
    Const END_COL As Long = 6 

    Const OUTPUT_COL_START As Long = 20 

    With Worksheets("datasummary") 
    'Load the values into an array 
    values = .Range(.Cells(1, 1), .Cells(199, 18)).Value 
    For rowCounter = 1 To 40 
     ReDim rowresults(1 To 1, START_COL To END_COL) 
     For colCounter = START_COL To END_COL 
'find average of AOIentries values 
     rowresults(1, colCounter) = Application.WorksheetFunction.Average(values((5 * rowCounter - 2), colCounter), values((5 * rowCounter - 2), colCounter + 6), values((5 * rowCounter - 2), colCounter + 12)) 

     Next colCounter 
'print row of results 
     .Range(.Cells(5 * rowCounter - 2, OUTPUT_COL_START), .Cells(5 * rowCounter - 2, OUTPUT_COL_START + END_COL - START_COL)).Value = rowresults 

     For colCounter = START_COL To END_COL 
'find average of RT values 
     rowresults(1, colCounter) = Application.WorksheetFunction.Average(values((5 * rowCounter - 1), colCounter), values((5 * rowCounter - 1), colCounter + 6), values((5 * rowCounter - 1), colCounter + 12)) 

     Next colCounter 
'print row of results 
     .Range(.Cells(5 * rowCounter - 1, OUTPUT_COL_START), .Cells(5 * rowCounter - 1, OUTPUT_COL_START + END_COL - START_COL)).Value = rowresults 

    Next rowCounter 

    End With 
End Sub 

这里是打印值，包括空白单元格的代码：

For r = 1 To UBound(d, 1) 
     k = d(r, COL_BLOCK) & "|" & d(r, COL_TRIAL) 'create key 
     If d(r, 19) = 1 Then 
     dBT(k) = dBT(k) + IIf(d(r, COL_AOI) = "AOI Entry", 1, 0) 'get count 
     Else: dBT(k) = "" 
     End If 
    Next r 

    'populate array with appropriate counts for each row 
    For r = 1 To UBound(d, 1) 
     k = d(r, 1) & "|" & d(r, 2) 'create key 
     resBT(r, 1) = dBT(k)   'get the count 
    Next r 
Call createsummarytable 
Call PopSummaryAOI(dBT) 

dBT.RemoveAll 

    For r = 1 To UBound(d, 1) 
     k = d(r, COL_BLOCK) & "|" & d(r, COL_TRIAL) 'create key 
     dBT(k) = d(r, COL_RT) 
    Next r 

至于我可以告诉（20 + 17）/ 2 =/= 12.33，而（20 + 17 + 0）/ 3 = 12.33，这个单元格完全是空白的，所以它不应该包含在平均值中。

Answer 1

当你调用.Range(.Cells(1, 1), .Cells(199, 18)).Value，你最终的Variant数组。 WorksheetFunction.Average对待Range s和Variant排列不同于它对待Variant s。如果你给它一个参数个人Variant，它投下他们对Double秒，铸造Empty到Double的结果为0如果你想让它忽略空白单元格，你需要通过它Range或Variant()：

Sub Example() 
    Dim test As Variant 
    test = Empty 'This is what you get from an EmptyCell.Value 
    Debug.Print CDbl(test) 'Prints 0. 
    Debug.Print WorksheetFunction.Average(test, 0, 10) 'Prints 3.33333333333333. 
    Range("A1").ClearContents 'Nothing in A1 now. 
    Debug.Print Range("A1").Value = Empty 'Prints True 
    Debug.Print WorksheetFunction.Average(Range("A1"), 0, 10) 'Prints 5 
End Sub