使用VBA在Excel上进行高级搜索和过滤

Question

我设法创建了一个代码，它使用visual basic在Excel数据库内搜索所有选项卡。但是，搜索只会告诉我信息所在的位置，并且不会显示信息。

下面的代码如下：

Sub SearchWordInEntireWorkbook() 
Dim ws As Worksheet 
Dim strWhat As String 
Dim cell As Range 
Dim Found As Boolean 
strWhat = Application.InputBox("What word do you want to search in this workbook?", "Search Word!", Type:=2) 
If strWhat = "" Then 
    MsgBox "No search word entered.", vbExclamation, "Search Cancelled!" 
    Exit Sub 
End If 

For Each ws In Worksheets 
    With ws.Cells 
     Set cell = .Find(what:=strWhat, lookat:=xlPart, MatchCase:=False) 
     If Not cell Is Nothing Then 
     Found = True 
     MsgBox "The Word " & strWhat & " is found in " & cell.Address(0, 0) & " on " & ws.Name & " sheet." 
     End If 
    End With 
Next ws 
If Not Found Then 
    MsgBox "The word " & strWhat & " is not found on any sheet in this workbook.", vbExclamation, "Word Not Found!" 
End If 
End Sub 

我需要的是，当你运行搜索，而不是告诉我在哪里，该数据位于要显示的数据。

请任何人都可以帮我解决这个问题吗？如果您需要任何其他信息，请告诉我。 据我所知，有

Answer 1

为我的意见的延续，而不是

Sub SearchWordInEntireWorkbook() 
    Dim ws As Worksheet 
    Dim strWhat As String 
    Dim cell As Range 
    Dim Found As Boolean 
    strWhat = Application.InputBox("What word do you want to search in this workbook?", "Search Word!", Type:=2) 
    If strWhat = "" Then 
     MsgBox "No search word entered.", vbExclamation, "Search Cancelled!" 
     Exit Sub 
    End If 

    For Each ws In Worksheets 
     With ws.Cells 
      Set cell = .Find(what:=strWhat, lookat:=xlPart, MatchCase:=False) 
      If Not cell Is Nothing Then 
      Found = True 
      'MsgBox "The Word " & strWhat & " is found in " & cell.Address(0, 0) & " on " & ws.Name & " sheet." 
      Application.Goto Sheets(cell.Parent.Name).range(cell.Address) 
'edit starts 
     ans = MsgBox("is this the one you r looking for. if so, say yes and quit, else say no and go to the next result", vbYesNo) 
     If ans = vbYes Then 
      Exit For 
     End If 
'edit ends 
      End If 
     End With 
    Next ws 
    If Not Found Then 
     MsgBox "The word " & strWhat & " is not found on any sheet in this workbook.", vbExclamation, "Word Not Found!" 
    End If 
    End Sub 

Answer 2

如果要添加存储在单元格中的数值，只是添加了一些报告值目前您报告了

MsgBox "The Word " & strWhat & " is found in " & cell.Address(0, 0) & " on " & ws.Name & " sheet." 

地址：

MsgBox "The Word " & strWhat & " is found in " & cell.Address(0, 0) & " on " & ws.Name & " sheet. The cell contains:" & Cell.Value 

Answer 3

如果这个词可以在多张纸上找到，这将过滤所有包含单词的表格

另外，如果用户输入野生字符，它将停止搜索CTER “*”

---

Option Explicit 

Public Sub SearchWordInEntireWorkbook() 
    Dim ws As Worksheet, findWhat As String, foundCell As Range, found As Boolean 

    findWhat = Application.InputBox("Enter word to search for in this workbook?", _ 
            "Search Word!", Type:=2) 
    If Len(findWhat) = 0 Or findWhat = "*" Then 
     MsgBox "Try again", vbExclamation, "Search Cancelled!" 
     Exit Sub 
    End If 

    For Each ws In ThisWorkbook.Worksheets 
     With ws.UsedRange 

      If ws.AutoFilterMode Then .AutoFilter 

      Set foundCell = .Find(What:=findWhat, _ 
            After:=.Cells(.Rows.Count, .Columns.Count), _ 
            LookAt:=xlPart, MatchCase:=False) 

      If Not foundCell Is Nothing Then 
       .AutoFilter Field:=foundCell.Column, Criteria1:=findWhat 
       found = True 
      Else 
       .Rows.Hidden = True 
      End If 
     End With 
    Next ws 

    If Not found Then 
     MsgBox "The word '" & findWhat & "' was not found in this workbook.", _ 
       vbExclamation, "Word Not Found!" 
    End If 
End Sub