在AWK

Question

阅读两个文件我有一个文件，它看起来像：

1 4 
2 4 
3 5 
4 4 
5 4 
6 1 
7 1 
8 1 
9 4 
10 4 
12 1 
13 1 
14 1 
15 1 
16 2 
19 3 
20 1 
21 1 
26 1 
28 3 
24 4 
29 4 
30 1 

塔1序列号和列2是值。我想计算的特定范围为例如间值的总和：总和在列2其是2和7（从列1）之间的值

我由下列AWK一个衬里来达到的这样的：

awk '{if ($1 >= 2 && $1 <= 7) x += $2 } END {print x}' file_name #output is 20 

的问题是，我想读其他文件2范围：3-9，2-6，12-20等

3 9 
2 6 
12 20 

我怎么能忽略的范围从文件2到AWK，而不是手动用if语句输入范围。如何在AWK中读取多个文件？

Answer 1

您可以通过几种方式读取多个文件。您可以在命令行中指定多个文件，在这种情况下，awk将读取每个文件一次，或者您可以使用getline从文件中读取一行。然而，在这种情况下，执行计算更加昂贵的事情可能是最简单的，只需通过file1对file2中指定的每个范围读取一次，但不要使用awk来读取范围。喜欢的东西：

while read lower upper; do 
awk '$1 >= lower && $1 <= upper{ x += $2 } END {print x}' \ 
    lower=$lower upper=$upper file1 
done < file2 

如果你只想要一次读文件1，你可以做更复杂的东西像（未经测试）：

awk 'NR==FNR{ lo[NR]=$1; hi[NR]=$2; next } 
    { for(i in lo) if($1 >= lo[i] && $1 <= hi[i]) sum[i]+=$2 } 
    END{ for(i in b) print "sum of " lo[i] " to " hi[i] ": " sum[i] }' file2 file1 

Answer 2

另外一个你可以尝试：

awk ' 
    NR==FNR{ 
    A[$1]=$2 
    next 
    } 
    { 
    t=0 
    for(i in A) if(i>=$1 && i<=$2) t+=A[i] 
    print t 
    } 
' file rangefile 

或在一行中：

awk 'NR==FNR{A[$1]=$2; next}{t=0; for(i in A) if(i>=$1 && i<=$2) t+=A[i]; print t}' file rangefile 

Answer 3

下面是使用awk一个办法：

awk 'NR==FNR { a[$1]=$2; next } { for (i in a) { i+=0; if (i>=$1 && i<=$2) s+=a[i] } print s; s=0 }' file1 file2 

结果：

20 
18 
10