批文件从文本文件中复制文件列表

Question

我正在尝试制作批文件以将文件从文本列表复制到文件夹。该代码被复制在这个论坛上，但它不起作用。

文本列表在桌面上。

LIST.TXT

，并包含，例如，

C：\用户\桌面\测试\ item1.ipt
C：\用户\桌面\测试\ item2.ipt
C：\ Users ... \ Desktop \ Test \ item3.ipt
C：\ Users ... \ Desktop \ Test \ item4.ipt
C：\ Users ... \ Desktop \ Test \ item5.ipt
C：\ Users ... \ Desktop \ Test \ item6.ipt

和我的批处理文件也在桌面上。

@echo off 
FOR /F "delims=" %%a IN (C:\Users\...\Desktop\list.txt) DO COPY "%%~a" "C:\Users\...\Desktop\Temp\%%~nxa" 

这两个文件（批处理和txt）都在桌面上，所以我可以删除文本文件的路径吗？

@echo off 
FOR /F "delims=" %%a IN (list.txt) DO COPY "%%~a" "C:\Users\...\Desktop\Temp\%%~nxa" 

感谢您的帮助。

编辑：理念是获取文本文件中的文件位置，因此文本文件中的目录是变量。

Answer 1

@echo off 
pushd "%userprofile%\Desktop" 
FOR /F "delims=" %%a IN (list.txt) DO COPY "%%~a" ".\Temp\%%~nxa" 
popd 

在上面的代码片断：

• pushd command：改变当前目录/文件夹，并通过POPD命令存储用于使用上一个文件夹/路径。
• %userprofile%是standard (built-in) Environment Variable
• 在".\Temp\%%~nxa"一个周期是一个directory component in a path representing the current directory。因此，".\Temp\%%~nxa"与"Temp\%%~nxa"具有相同的效果。
• POPD指令：Change directory back to the path/folder most recently stored by the PUSHD command。

编辑。如果list.txt为空，或者只包含空行和标准分隔符，或者如果它以某些控制字符开始，则'for/F'循环上面不做任何事情。 NULL字符，或者是否它被利用UTF-16编码：保存

==> type null_and_data.txt 
1st line 
2nd 
3rd 

==> FOR /F "delims=" %a IN (null_and_data.txt) DO @echo "%~a" 

==> powershell -c "(type null_and_data.txt -Encoding byte -TotalCount 16) -Join ','" 
0,49,115,116,32,108,105,110,101,32,13,10,50,110,100,13 

==> 

一些上述情况（特别是，后者的一个）可以可以通过使用type command如下解决：

@echo off 
pushd "%userprofile%\Desktop" 
FOR /F "delims=" %%a IN ('type list.txt') DO COPY "%%~a" ".\Temp\%%~nxa" 
popd 

例如：

==> FOR /F "delims=" %a IN (fileUTF16LEBOM.txt) DO @echo "%~a" 

==> type fileUTF16LEBOM.txt 
x 
y 

==> FOR /F "delims=" %a IN ('type fileUTF16LEBOM.txt') DO @echo "%~a" 
"x" 
"y" 

==>