如何在Inno Setup中创建“典型”和“自定义”安装选项？

我见过很多软件让用户可以选择安装具有典型设置的软件，或者允许用户选择他们喜欢的设置（如是否需要桌面图标）。我如何使用Inno Setup来做到这一点？如何在Inno Setup中创建“典型”和“自定义”安装选项？

2010-12-21 Blossoming_Flower

有这样做只是这与创新安装安装的样本。查看Inno Setup自带的Inno Setup 5 \ Examples \ Components.iss文件。

的例子显示了打造“全”，“紧凑型”，并在一个单一的Setup.exe文件“自定义”安装选项。

; -- Components.iss -- 
; Demonstrates a components-based installation. 

; SEE THE DOCUMENTATION FOR DETAILS ON CREATING .ISS SCRIPT FILES! 

[Setup] 
AppName=My Program 
AppVersion=1.5 
DefaultDirName={pf}\My Program 
DefaultGroupName=My Program 
UninstallDisplayIcon={app}\MyProg.exe 
OutputDir=userdocs:Inno Setup Examples Output 

[Types] 
Name: "full"; Description: "Full installation" 
Name: "compact"; Description: "Compact installation" 
Name: "custom"; Description: "Custom installation"; Flags: iscustom 

[Components] 
Name: "program"; Description: "Program Files"; Types: full compact custom; Flags: fixed 
Name: "help"; Description: "Help File"; Types: full 
Name: "readme"; Description: "Readme File"; Types: full 
Name: "readme\en"; Description: "English"; Flags: exclusive 
Name: "readme\de"; Description: "German"; Flags: exclusive 

[Files] 
Source: "MyProg.exe"; DestDir: "{app}"; Components: program 
Source: "MyProg.chm"; DestDir: "{app}"; Components: help 
Source: "Readme.txt"; DestDir: "{app}"; Components: readme\en; Flags: isreadme 
Source: "Readme-German.txt"; DestName: "Liesmich.txt"; DestDir: "{app}"; Components: readme\de; Flags: isreadme 

[Icons] 
Name: "{group}\My Program"; Filename: "{app}\MyProg.exe"

来源

2010-12-21 19:06:47

我认为你应该使用[Code]科

由肯·怀特只有作品与文件提供给包括/从安装中排除的答案。

它不会禁用目录页或询问用户，如果他愿意与否桌面图标的页面。 （例如）

退房的例子：CodeClasses.iss内C:\Program Files\Inno Setup 5\Examples

来源

2014-11-18 11:15:02 SylafrsOne

没有一个提到的禁止目录。页。 OP询问如何进行设置，使用户能够选择他们喜欢的设置（比如他们是否需要桌面图标）。“*这正是Ken在答案中所展示的。此外，您不需要使用`[Code]`部分来禁用dir。页。 – TLama 2014-11-18 11:19:13

如何在Inno Setup中创建“典型”和“自定义”安装选项？

回答

相关问题