在Perl中使用拆分和修剪的地图

Question

如何使用带分割功能的地图来修剪组成部分：$ a，$ b，$ c和$ d; $行？

my ($a, $b, $c, $d, $e) = split(/\t/, $line); 

# Perl trim function to remove whitespace from the start and end of the string 
sub trim($) 
{ 
    my $string = shift; 
    $string =~ s/^\s+//; 
    $string =~ s/\s+$//; 
    return $string; 
} 

Answer 1

这应该工作：

my ($a, $b, $c, $d, $e) = map {trim ($_)} (split(/\t/, $line)); 

顺便说一句，这是一个小点，但你不应该使用$ a和$ b作为变量名。

Answer 2

map有两个输入端：

• 一个表达式或块：这将是trim表达式（你没有写自己的 - 这是对CPAN）
• ，操作列表于：这应该是split的输出：

use String::Util 'trim'; 
my @values = map { trim($_) } split /\t/, $line; 

Answer 3

不要使用原型你的功能上的($)除非你需要他们。

my ($a, $b, $c, $d, $e) = 
    map {s/^\s+|\s+$//g; $_} ## Notice the `, $_` this is common 
    , split(/\t/, $line, 5) 
; 

在上面不要忘记s///返回更换计数 - 不$_。所以，我们明确地这样做。

或者更简单地说：

my @values = map {s/^\s+|\s+$//g; $_}, split(/\t/, $line, 5), $line 

Answer 4

只是为了多种：

my @trimmed = grep { s/^\s*|\s*$//g } split /\t/, $line; 

grep作为上列出的过滤器。这就是为什么需要在正则表达式中将\s+更改为\s*的原因。强制匹配0或更多空格可防止grep过滤掉列表中没有前导或尾随空格的项目。

Answer 5

你也可以在这里使用“foreach”。

foreach my $i ($a, $b, $c, $d, $e) { 
    $i=trim($i); 
} 

Answer 6

当我修剪一个字符串时，我经常不想保留原文。有一个sub的抽象，但也不必大惊小怪临时值。

事实证明，我们所能做的只是这一点，因为perlsub解释说：

中显示出来的阵列@_传入任何参数。因此，如果您使用两个参数调用函数，那么这些函数将存储在$_[0]和$_[1]中。数组@_是一个本地数组，但其元素是实际标量参数的别名。特别是，如果更新了元素$_[0]，则会更新相应的参数（或者如果它不可更新，则会发生错误）。

在你的情况，trim成为

sub trim { 
    for (@_) { 
    s/^ \s+ //x; 
    s/ \s+ $//x; 
    } 
    wantarray ? @_ : $_[0]; 
} 

记住map和for是堂兄弟，所以在trim循环，你不再需要map。例如

my $line = "1\t 2\t3 \t 4 \t 5 \n";  
my ($a, $b, $c, $d, $e) = split(/\t/, $line);  

print "BEFORE: [", join("] [" => $a, $b, $c, $d), "]\n"; 
trim $a, $b, $c, $d; 
print "AFTER: [", join("] [" => $a, $b, $c, $d), "]\n"; 

输出：

BEFORE: [1] [ 2] [3 ] [ 4 ] 
AFTER: [1] [2] [3] [4]