使用NSIS检查.NET4.5 +

所有的，我知道以下方法检查NSIS中的框架版本。对于.NET4.0 +我目前使用使用NSIS检查.NET4.5 +

Function IsDotNetInstalled 

    StrCpy $0 "0" 
    StrCpy $1 "SOFTWARE\Microsoft\.NETFramework" ; Registry entry to look in. 
    StrCpy $2 0 

    StartEnum: 
    ; Enumerate the versions installed. 
    EnumRegKey $3 HKLM "$1\policy" $2 

    ; If we don't find any versions installed, it's not here. 
    StrCmp $3 "" noDotNet notEmpty 

    ; We found something. 
    notEmpty: 
     ; Find out if the RegKey starts with 'v'. 
     ; If it doesn't, goto the next key. 
     StrCpy $4 $3 1 0 
     StrCmp $4 "v" +1 goNext 
     StrCpy $4 $3 1 1 

     ; It starts with 'v'. Now check to see how the installed major version 
     ; relates to our required major version. 
     ; If it's equal check the minor version, if it's greater, 
     ; we found a good RegKey. 
     IntCmp $4 ${DOT_MAJOR} +1 goNext yesDotNetReg 
     ; Check the minor version. If it's equal or greater to our requested 
     ; version then we're good. 
     StrCpy $4 $3 1 3 
     IntCmp $4 ${DOT_MINOR} yesDotNetReg goNext yesDotNetReg 

    goNext: 
     ; Go to the next RegKey. 
     IntOp $2 $2 + 1 
     goto StartEnum 

    yesDotNetReg: 
     ; Now that we've found a good RegKey, let's make sure it's actually 
     ; installed by getting the install path and checking to see if the 
     ; mscorlib.dll exists. 
     EnumRegValue $2 HKLM "$1\policy\$3" 0 
     ; $2 should equal whatever comes after the major and minor versions 
     ; (ie, v1.1.4322) 
     StrCmp $2 "" noDotNet 
     ReadRegStr $4 HKLM $1 "InstallRoot" 
     ; Hopefully the install root isn't empty. 
     StrCmp $4 "" noDotNet 
     ; Build the actuall directory path to mscorlib.dll. 
     StrCpy $4 "$4$3.$2\mscorlib.dll" 
     IfFileExists $4 yesDotNet noDotNet 

    noDotNet: 
     ; No, something went wrong along the way. Looks like the 
     ; proper .NET Framework isn't installed. 
     MessageBox MB_ICONEXCLAMATION "To install UserCost, Microsoft's .NET Framework v${DOT_MAJOR}.${DOT_MINOR} \ 
     (or higher) must be installed. Cannot proceed with the installation!" 
     ${OpenURL} "${WWW_MS_DOTNET4}" 
     Abort 

    yesDotNet: 
     ; Everything checks out. Proceed with the rest of the installation. 

FunctionEnd

这都非常好，.NET4.0，但现在我已经延长我的应用程序利用async/await功能，随后需要用户安装.NET4.5 +。上述方法不适用，因为.NET4.5的安装现在不使用regestry路径“HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft.NETFramework \ Policy”来存储任何新信息，即该路径似乎不具有值.NET4.0和4.5之间的变化现在我已经看到了以下职位：

NSIS Installer with .NET 4.5

它使用的注册表路径/进入“HKEY_LOCAL_MACHINE \ SOFTWARE \微软\ NET Framework安装\ NDP”做检查。现在，这也是机器人的工作，因为入口不会从.NET4.0更改为4.5。我注意到有和称为'HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft.NETFramework \ v4.0.30319 \ SKUs.NETFramework，版本= v4的条目。 5'我可以用它来检查框架版本吗？

是否有使用NSIS检查.NET4.5的方法的一条主线？

谢谢你的时间。

注：随后一些安装.NET4.5我的用户已经执行有注册表值

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full

命名为Release一个DWORD值不378389，但378181。进行此更改似乎可以解决问题，因为Release的条目不在.NET4.5及更低版本的注册表中。

来源

2013-03-05 MoonKnight

是的，有来检查是否安装了.NET Framework 4.5的官方方式，即使它不是真正友好。从MSDN：

您可以测试是否在.NET Framework 4.5或.NET Framework 4是通过检查注册表中的子项HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full名为Release一个DWORD值安装。此DWORD的存在表示.NET Framework 4.5已安装在该计算机上。 Release的值是一个版本号。要确定是否安装.NET Framework 4.5的最终发行版本中，检查是否等于或大于378389.

http://msdn.microsoft.com/en-us/library/hh925568.aspx

这意味着你得先检查4.0的值然后检查HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full中是否存在名为Release的值，如果是，则已安装4.5（我认为您可以跳过对预发布版本的检查）。

编辑：检查this post这里SO有关检测旧的安装.NET版本，这对于MSDN article版本4.5.x区分细节。

来源

2013-03-05 15:35:09

这是一个高质量的答案。这些信息在哪里由微软提供 - 或者我们是否期望找到自己的信息？感谢您的时间... – MoonKnight 2013-03-05 15:42:03

我忘了引用[源代码]（http://msdn.microsoft.com/en-us/library/hh925568.aspx）。 – 2013-03-05 15:44:47

刚刚找到它。再次感谢... – MoonKnight 2013-03-05 15:49:20

这是我编写的一个函数，用于检查并下载.NET 4.5。此外，代码还会查找.NET安装程序的本地副本 - 以防将安装程序放到CD或USB驱动器或其他设备上。支持无提示安装和非安静安装，以及设置Reboot标志。该函数是自包含的，但希望包含LogicLib（包含在基本的NSIS安装中）。

这是我为我的Rachel故事书的安装程序编写的代码。

Function CheckAndDownloadDotNet45 
# Let's see if the user has the .NET Framework 4.5 installed on their system or not 
# Remember: you need Vista SP2 or 7 SP1. It is built in to Windows 8, and not needed 
# In case you're wondering, running this code on Windows 8 will correctly return is_equal 
# or is_greater (maybe Microsoft releases .NET 4.5 SP1 for example) 

# Set up our Variables 
Var /GLOBAL dotNET45IsThere 
Var /GLOBAL dotNET_CMD_LINE 
Var /GLOBAL EXIT_CODE 

ReadRegDWORD $dotNET45IsThere HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" "Release" 
IntCmp $dotNET45IsThere 378389 is_equal is_less is_greater 

is_equal: 
    Goto done_compare_not_needed 
is_greater: 
    # Useful if, for example, Microsoft releases .NET 4.5 SP1 
    # We want to be able to simply skip install since it's not 
    # needed on this system 
    Goto done_compare_not_needed 
is_less: 
    Goto done_compare_needed 

done_compare_needed: 
    #.NET Framework 4.5 install is *NEEDED* 

    # Microsoft Download Center EXE: 
    # Web Bootstrapper: http://go.microsoft.com/fwlink/?LinkId=225704 
    # Full Download: http://go.microsoft.com/fwlink/?LinkId=225702 

    # Setup looks for components\dotNET45Full.exe relative to the install EXE location 
    # This allows the installer to be placed on a USB stick (for computers without internet connections) 
    # If the .NET Framework 4.5 installer is *NOT* found, Setup will connect to Microsoft's website 
    # and download it for you 

    # Reboot Required with these Exit Codes: 
    # 1641 or 3010 

    # Command Line Switches: 
    # /showrmui /passive /norestart 

    # Silent Command Line Switches: 
    # /q /norestart 


    # Let's see if the user is doing a Silent install or not 
    IfSilent is_quiet is_not_quiet 

    is_quiet: 
     StrCpy $dotNET_CMD_LINE "/q /norestart" 
     Goto LookForLocalFile 
    is_not_quiet: 
     StrCpy $dotNET_CMD_LINE "/showrmui /passive /norestart" 
     Goto LookForLocalFile 

    LookForLocalFile: 
     # Let's see if the user stored the Full Installer 
     IfFileExists "$EXEPATH\components\dotNET45Full.exe" do_local_install do_network_install 

     do_local_install: 
      # .NET Framework found on the local disk. Use this copy 

      ExecWait '"$EXEPATH\components\dotNET45Full.exe" $dotNET_CMD_LINE' $EXIT_CODE 
      Goto is_reboot_requested 

     # Now, let's Download the .NET 
     do_network_install: 

      Var /GLOBAL dotNetDidDownload 
      NSISdl::download "http://go.microsoft.com/fwlink/?LinkId=225704" "$TEMP\dotNET45Web.exe" $dotNetDidDownload 

      StrCmp $dotNetDidDownload success fail 
      success: 
       ExecWait '"$TEMP\dotNET45Web.exe" $dotNET_CMD_LINE' $EXIT_CODE 
       Goto is_reboot_requested 

      fail: 
       MessageBox MB_OK|MB_ICONEXCLAMATION "Unable to download .NET Framework. ${PRODUCT_NAME} will be installed, but will not function without the Framework!" 
       Goto done_dotNET_function 

      # $EXIT_CODE contains the return codes. 1641 and 3010 means a Reboot has been requested 
      is_reboot_requested: 
       ${If} $EXIT_CODE = 1641 
       ${OrIf} $EXIT_CODE = 3010 
        SetRebootFlag true 
       ${EndIf} 

done_compare_not_needed: 
    # Done dotNET Install 
    Goto done_dotNET_function 

#exit the function 
done_dotNET_function: 

FunctionEnd

来源

2013-03-07 02:15:59

感谢您的代码。我会发布我最后一起去... – MoonKnight 2013-03-07 09:03:56

没问题。我刚刚完成了为自己写的功能，并通过Twitter偶然发现了这个页面，并指出“为什么不呢？”我喜欢你的代码，尽管我没有将.NET作为一个选项（因为程序需要它）。还有一点允许.NET安装程序的本地副本运行，这样您的安装程序就可以放置在CD或USB密钥上。我注意到你的代码没有在你的MessageBox调用中使用/ SD（以允许静默操作 - 请随时查看我如何处理它）。 – 2013-03-08 00:17:07

此代码存在问题。 “变量”dotNetDidDownload“未引用或从未设置”。您应该在NSISdl :: download调用之后从堆栈中弹出返回值，而不是将其作为参数提供。同时'StrCmp $ dotNetDidDownload失败成功'应该是'StrCmp $ dotNetDidDownload“成功”成功失败“。 – fretje 2015-03-02 18:20:11

最后，我去了以下函数，它利用了上面的答案。该方法首先创建一个目录"$INSTDIR\dotNETFramework"它包含了.NET Web安装程序：

Function CheckAndInstallDotNet 
    ; Installer dotNetFx45_Full_setup.exe avalible from http://msdn.microsoft.com/en-us/library/5a4x27ek.aspx 
    ; Magic numbers from http://msdn.microsoft.com/en-us/library/ee942965.aspx 
    ClearErrors 
    ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" "Release" 
    IfErrors NotDetected 
    ${If} $0 >= 378389 
     DetailPrint "Microsoft .NET Framework 4.5 is installed ($0)" 
    ${Else} 
    NotDetected: 
     MessageBox MB_YESNO|MB_ICONQUESTION ".NET Framework 4.5+ is required for ProgramX2013, \ 
      do you want to launch the web installer? This requires a valid internet connection." IDYES InstallDotNet IDNO Cancel 
     Cancel: 
      MessageBox MB_ICONEXCLAMATION "To install ProgramX, Microsoft's .NET Framework v${DOT_MAJOR}.${DOT_MINOR} \ 
       (or higher) must be installed. Cannot proceed with the installation!" 
      ${OpenURL} "${WWW_MS_DOTNET4_5}" 
      RMDir /r "$INSTDIR" 
      SetOutPath "$PROGRAMFILES" 
      RMDir "$INSTDIR" 
      Abort 

     ; Install .NET4.5. 
     InstallDotNet: 
      DetailPrint "Installing Microsoft .NET Framework 4.5" 
      SetDetailsPrint listonly 
      ExecWait '"$INSTDIR\dotNETFramework\dotNetFx45_Full_setup.exe" /passive /norestart' $0 
      ${If} $0 == 3010 
      ${OrIf} $0 == 1641 
       DetailPrint "Microsoft .NET Framework 4.5 installer requested reboot." 
       SetRebootFlag true 
      ${EndIf} 
      SetDetailsPrint lastused 
      DetailPrint "Microsoft .NET Framework 4.5 installer returned $0" 
    ${EndIf} 

    ; Now remove the dotNETFramework directory and contents. 
    RMDir /r "$INSTDIR\dotNETFramework" 
FunctionEnd

这种方法seemlessley启动.NET4.5安装程序，如果有互联网连接，并返回在安装完成后。

我希望这可以帮助别人。

来源

2013-03-07 09:07:26 MoonKnight

+1，谢谢，正是我在找的东西。 – 2013-09-05 11:09:34

@ sa_ddam213 note我刚刚收到客户端通知，他说他在XP中自动运行.NET Web安装程序时遇到了问题。我正在研究此问题，并会在/如果我得到一个解决方案时发布解决方案... – MoonKnight 2013-09-05 13:28:05

请参阅http://stackoverflow.com/questions/11027185/net-4-5-rc-framework-clr-windows-xp-compatibility 。 – MoonKnight 2013-09-05 15:01:17

既然.NET Framework 4.5.1可用，则需要检查注册表中名为Release的DWORD的实际值，而不仅仅是它的存在。

值为378758表示安装了.NET Framework 4.5.1，但是，如在Windows 8.1上的here这个值为378675。

来源

2013-12-12 09:29:37 JasonMcF

如果您正在寻找与.NET框架选项4.0+（及以上），包括

.NET 4.5
.NET 4.5.1

你也可以检查此插件NSIS：DotNetChecker

来源

2014-10-07 01:49:39 Mehrad

链接被破坏... – MoonKnight 2014-10-08 09:42:48

@Killercam谢谢你的抬头。修复。 – Mehrad 2014-10-08 10:05:06

这是一个简单的NSIS函数，用于检查.NET版本（适用于4.5,4.5.1,4.5.2和4.6）。数字比较基于MSDN。

将在您的NSIS文件中的函数，并调用它像这样

Call CheckForDotVersion45Up 
Pop $0 
DetailPrint $0

下面是函数。

; returns a numeric value on the stack, ranging from 0 to 450, 451, 452 or 460. 0 means nothing found, the other values mean at least that version 
Function CheckForDotVersion45Up 

    ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" Release 

    IntCmp $0 393295 is46 isbelow46 is46 

    isbelow46: 
    IntCmp $0 379893 is452 isbelow452 is452 

    isbelow452: 
    IntCmp $0 378675 is451 isbelow451 is451 

    isbelow451: 
    IntCmp $0 378389 is45 isbelow45 is45 

    isbelow45: 
    Push 0 
    Return 

    is46: 
    Push 460 
    Return 

    is452: 
    Push 452 
    Return 

    is451: 
    Push 451 
    Return 

    is45: 
    Push 45 
    Return 

FunctionEnd

来源

2015-10-27 11:21:46

使用NSIS检查.NET4.5 +

回答

相关问题