excel 2010 vba使用不同颜色突出显示不同颜色的单元格横跨多个列的不同重复值

Question

如何使用不同颜色突出显示excel 2010中的多个单元格跨多个列。 我发现这个代码，但它适用于一列。

Sub Highlight_Duplicate_Entry() 
     Dim cel As Variant 
     Dim myrng As Range 
     Dim clr As Long 

     Set myrng = Range("A2:A" & Range("A65536").End(xlUp).Row) 
     myrng.Interior.ColorIndex = xlNone 
     clr = 3 

     For Each cel In myrng 
      If Application.WorksheetFunction.CountIf(myrng, cel) > 1 Then 
       If WorksheetFunction.CountIf(Range("A2:A" & cel.Row), cel) = 1 Then 
       cel.Interior.ColorIndex = clr 
       clr = clr + 1 
       Else 
       cel.Interior.ColorIndex = myrng.Cells(WorksheetFunction.Match(cel.Value, myrng, False), 1).Interior.ColorIndex 
       End If 
      End If 
     Next 
    End Sub 

Answer 1

您需要更改范围覆盖多个列，这会导致您的Match功能失效。将其替换为Find。下面的子文件将找到指定范围内的任何重复项，并用不同的颜色突出显示它们。

改为如下代码：

Sub Highlight_Duplicate_Entry() 
    Dim ws As Worksheet 
    Dim cell As Range 
    Dim myrng As Range 
    Dim clr As Long 
    Dim lastCell As Range 

    Set ws = ThisWorkbook.Sheets("Sheet1") 
    Set myrng = ws.Range("A2:d" & Range("A" & ws.Rows.Count).End(xlUp).Row) 
    With myrng 
     Set lastCell = .Cells(.Cells.Count) 
    End With 
    myrng.Interior.ColorIndex = xlNone 
    clr = 3 

    For Each cell In myrng 
     If Application.WorksheetFunction.CountIf(myrng, cell) > 1 Then 
      ' addresses will match for first instance of value in range 
      If myrng.Find(what:=cell, lookat:=xlWhole, MatchCase:=False, after:=lastCell).Address = cell.Address Then 
       ' set the color for this value (will be used throughout the range) 
       cell.Interior.ColorIndex = clr 
       clr = clr + 1 
      Else 
       ' if not the first instance, set color to match the first instance 
       cell.Interior.ColorIndex = myrng.Find(what:=cell, lookat:=xlWhole, MatchCase:=False, after:=lastCell).Interior.ColorIndex 
      End If 
     End If 
    Next 
End Sub 

添加基于注释的结果的屏幕截图如下，以帮助阐明如何工作的。每组副本都以单独的颜色突出显示。不重复的值不是彩色的：