日期转换为周数

嗨不确定是否有人可以帮助我。日期转换为周数

如何将当前日期转换为批处理脚本中的星期编号？

我只知道如何从我的电脑生成当前日期。％DATE％

例如。 2017年3月16日是11周

2017-03-16 lcc

另外，从该批处理文件用一个简单的一行代码调用PowerShell的：

@for /f %%a in ('powershell.exe get-date -UFormat %%V') do @set WeekInYear=%%a

来源

2017-03-16 09:18:33 Filipus

虽然PowerShell比批处理文件强大得多，这个“简单单线程”使用了470 KB大小的'powershell.exe'文件，因此它需要几秒__（在我的测试中为6.96）来获得通过任何其他方法立即获得的相同结果！建议可能是：不要使用PowerShell进行简单的一次性计算，比如这个... – Aacini

我的SSD可能会歪曲我自己的结果，因为在我的系统上运行该批处理的时间不到一秒钟。但是我同意Aacini的观点，即有时通往简约的道路已经付出代价！ – Filipus

使用this：

@echo off 
set "weekn=" 

    for /f %%W in (
     'mshta vbscript:Execute("createobject(""scripting.filesystemobject"").GetStandardStream(1).writeline(DatePart(""ww"",Now()))"^^^&close^)' 
    ) do @( 
    set "weekn=%%W" 
    ) 

echo %weekn%

来源

2017-03-16 06:30:42 npocmaka

它完美的作品！但for循环中的句子意味着什么？ – lcc

@lcc'mshta'是内置的工具，它可以用'mshta vbscript：..'或'mshta javascript：...'打开'html'文件（也可以访问文件系统的脚本）在其标题中注入可执行代码。尽管通常需要令人讨厌的转义，但写入控制台并不容易（需要'GetStandardStream（1）'和一个有效的管道），这对于短表达式很方便。 – npocmaka

你知道JScript的等价方法吗？ – Aacini

纯批解决方案。信贷Ritchie Lawrence

@echo off & setlocal ENABLEEXTENSIONS 
call :DateToWeek 2017 03 16 yn cw dw 
echo/Today (in ISO 8601 Week Date format) is: %yn%-W%cw%-%dw% 
pause 
goto :EOF 



::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
:DateToWeek %yy% %mm% %dd% yn cw dw 
:: 
:: By: Ritchie Lawrence, Updated 2002-11-20. Version 1.1 
:: 
:: Func: Returns an ISO 8601 Week date from a calendar date. 
::  For NT4/2000/XP/2003. 
:: 
:: Args: %1 year component to be converted, 2 or 4 digits (by val) 
::  %2 month component to be converted, leading zero ok (by val) 
::  %3 day of month to be converted, leading zero ok (by val) 
::  %4 var to receive year, 4 digits (by ref) 
::  %5 var to receive calendar week, 2 digits, 01 to 53 (by ref) 
::  %6 var to receive day of week, 1 digit, 1 to 7 (by ref) 
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
setlocal ENABLEEXTENSIONS 
set yy=%1&set mm=%2&set dd=%3 
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%) 
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,Jd=153*m+2 
set /a Jd=Jd/5+dd+y*365+y/4-y/100+y/400-32045 
set /a y=yy+4798,Jp=y*365+y/4-y/100+y/400-31738,t=Jp+3,Jp=t-t%%7 
set /a y=yy+4799,Jt=y*365+y/4-y/100+y/400-31738,t=Jt+3,Jt=t-t%%7 
set /a y=yy+4800,Jn=y*365+y/4-y/100+y/400-31738,t=Jn+3,Jn=t-t%%7 
set /a Jr=%Jp%,yn=yy-1,yn+=Jd/Jt,yn+=Jd/Jn 
if %Jd% GEQ %Jn% (set /a Jr=%Jn%) else (if %Jd% GEQ %Jt% set /a Jr=%Jt%) 
set /a diff=Jd-Jr,cw=diff/7+1,wd=diff%%7,wd+=1 
if %cw% LSS 10 set cw=0%cw% 
endlocal&set %4=%yn%&set %5=%cw%&set %6=%wd%&goto :EOF

来源

2017-03-16 13:07:33 Squashman

这种日期格式是独立的吗？ – npocmaka

日期转换为周数

回答

相关问题