在这里稍稍晚点来参加派对,但是您可以创建一个存储过程来建立跟踪,然后将其设置为在启动时运行。
USE master;
GO
-- define the proc
CREATE PROCEDURE usp_MakeMyTraceAtStartup AS
DECLARE @TraceID INT;
DECLARE @on BIT = 1;
EXEC sp_trace_create @TraceID output, 6, 'c:\mypath\mytraceout.trc', 5, NULL;
-- event 25 is a deadlock; see http://msdn.microsoft.com/en-us/library/ms186265.aspx
EXEC sp_trace_setevent @TraceID, 25, 6, @on; -- NTUserName
EXEC sp_trace_setevent @TraceID, 25, 7, @on; -- NTDomainName
EXEC sp_trace_setevent @TraceID, 25, 8, @on; -- HostName
EXEC sp_trace_setevent @TraceID, 25, 10, @on; -- ApplicationName
EXEC sp_trace_setevent @TraceID, 25, 11, @on; -- LoginName
EXEC sp_trace_setevent @TraceID, 25, 12, @on; -- SPID
EXEC sp_trace_setevent @TraceID, 25, 14, @on; -- StartTime
EXEC sp_trace_setevent @TraceID, 25, 23, @on; -- Success
EXEC sp_trace_setevent @TraceID, 25, 26, @on; -- ServerName
EXEC sp_trace_setevent @TraceID, 25, 31, @on; -- Error
EXEC sp_trace_setevent @TraceID, 25, 35, @on; -- DatabaseName
EXEC sp_trace_setevent @TraceID, 25, 60, @on; -- IsSystem
EXEC sp_trace_setevent @TraceID, 25, 64, @on; -- SessionLoginName
-- whatever other columns you want to audit
-- turn it on
EXEC sp_trace_setstatus @TraceID, 1;
GO
-- set it to run automatically at startup
EXEC sp_procoption 'usp_MakeMyTraceAtStartup', 'startup', 'true';
GO
SQL Server 2005及更高版本支持跟踪。
好吧,在这种情况下,我所得到的仅仅是受害者的SQL,也只是最高级的SQL正在执行。如果我得到一个死锁图,我可以很容易地找到哪个是导致死锁的确切sql。例如,如果一个存储过程调用另一个,然后再次调用另一个存储过程,那么发生死锁的时候,我会使用分析器得到涉及死锁的最内部的sql,但如果没有它们,它们将不会相同。因此我真的很想找到踪迹。 – Nikhil 2009-11-12 06:35:02