我很抱歉,如果这个问题已被问到,但我似乎无法找到我正在寻找什么。我希望能够找到XP(使用cmd)比特定日期更早的文件。我想要做一些像30天以前的DIR/FIND文件。如何获取比特定日期早的文件?
以下不起作用,但希望它会给你一个我想要做的事情的想法。
FOR /f %%f IN ('DIR /b /t -30 I:\FOLDER1\*.pdf') DO move /Y Z:\FOLDER1\%%f "I:\FOLDER2\"
谢谢!
我很抱歉,如果这个问题已被问到,但我似乎无法找到我正在寻找什么。我希望能够找到XP(使用cmd)比特定日期更早的文件。我想要做一些像30天以前的DIR/FIND文件。如何获取比特定日期早的文件?
以下不起作用,但希望它会给你一个我想要做的事情的想法。
FOR /f %%f IN ('DIR /b /t -30 I:\FOLDER1\*.pdf') DO move /Y Z:\FOLDER1\%%f "I:\FOLDER2\"
谢谢!
Julian日期函数从DosTips.com function library
采取先使用XCOPY/L/d获得已修改内过去30天的文件列表:保存到排除列表中。
然后使用XCOPY/L通过FINDSTR获取所有文件和管道,从排除列表中排除文件并将结果保存到包含列表。
最后遍历包括列表和移动这些文件
@echo off
setlocal
set src="I:\FOLDER1\*.pdf"
set dest="I:\FOLDER2"
set incl="%temp%\includeFiles%random%.txt"
set excl="%temp%\excludeFiles%random%.txt"
call :jdate jd
set /a jd-=30
call :jdate2date jd yyyy mm dd
xcopy %src% %dest% /d:%mm%-%dd%-%yyyy% /l | findstr /vxrc:"[0-9]* File(s)" >%excl%
xcopy %src% %dest% /l | findstr /vxrc:"[0-9]* File(s)" | findstr /vixlg:%excl% >%incl%
set /a "fail=0, ok=0"
for /f "usebackq eol=: delims=" %%F in (%incl%) do (
move /y "%%F" %dest% >nul 2>&1 && (
echo "%%F"
set /a "ok+=1"
) || (
>&2 echo ERROR: Unable to move "%%F"
set /a "fail+=1"
)
)
echo ----------------------
echo Moved %ok% files
if %fail% gtr 0 echo Failed to move %fail% files
del %excl%
del %incl%
exit /b %fail%
:jdate2date JD YYYY MM DD -- converts julian days to gregorian date format
:: -- JD [in] - julian days
:: -- YYYY [out] - gregorian year, i.e. 2006
:: -- MM [out] - gregorian month, i.e. 12 for december
:: -- DD [out] - gregorian day, i.e. 31
:$reference http://aa.usno.navy.mil/faq/docs/JD_Formula.html
:$created 20060101 :$changed 20080219 :$categories DateAndTime
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set /a L= %~1+68569, N= 4*L/146097, L= L-(146097*N+3)/4, I= 4000*(L+1)/1461001
set /a L= L-1461*I/4+31, J= 80*L/2447, K= L-2447*J/80, L= J/11
set /a J= J+2-12*L, I= 100*(N-49)+I+L
set /a YYYY= I, MM=100+J, DD=100+K
set MM=%MM:~-2%
set DD=%DD:~-2%
(ENDLOCAL & REM RETURN VALUES
IF "%~2" NEQ "" (SET %~2=%YYYY%) ELSE echo.%YYYY%
IF "%~3" NEQ "" (SET %~3=%MM%) ELSE echo.%MM%
IF "%~4" NEQ "" (SET %~4=%DD%) ELSE echo.%DD%
)
EXIT /b
:jdate JD DateStr -- converts a date string to julian day number with respect to regional date format
:: -- JD [out,opt] - julian days
:: -- DateStr [in,opt] - date string, e.g. "03/31/2006" or "Fri 03/31/2006" or "31.3.2006"
:$reference http://groups.google.com/group/alt.msdos.batch.nt/browse_frm/thread/a0c34d593e782e94/50ed3430b6446af8#50ed3430b6446af8
:$created 20060101 :$changed 20090328 :$categories DateAndTime
:$source http://www.dostips.com
SETLOCAL
set DateStr=%~2&if "%~2"=="" set DateStr=%date%
for /f "skip=1 tokens=2-4 delims=(-)" %%a in ('"echo.|date"') do (
for /f "tokens=1-3 delims=/.- " %%A in ("%DateStr:* =%") do (
set %%a=%%A&set %%b=%%B&set %%c=%%C))
set /a "yy=10000%yy% %%10000,mm=100%mm% %% 100,dd=100%dd% %% 100"
if %yy% LSS 100 set /a yy+=2000 &rem Adds 2000 to two digit years
set /a JD=dd-32075+1461*(yy+4800+(mm-14)/12)/4+367*(mm-2-(mm-14)/12*12)/12-3*((yy+4900+(mm-14)/12)/100)/4
ENDLOCAL & IF "%~1" NEQ "" (SET %~1=%JD%) ELSE (echo.%JD%)
EXIT /b
我没有使用XCOPY /排除选项,因为它把这些文件具有隐含的通配符。因此,如果您指定*而不是* .pdf,那么名为TEST的排除文件也会导致名为TEST1,TEST.TXT和TEST.EXE的文件也被排除。
在使用多个文字搜索字符串进行搜索时,需要使用FINDSTR/I选项来弥补FINDSTR错误。应该不需要/ I选项,但使用多个文字搜索字符串执行区分大小写的搜索可能会导致错误的结果。
使用forfiles
:
forfiles /p "i:\folder1" /m *.pdf /d -30 /c "move /y z:\folder1\@file i:\folder2"
forfiles在XP上不起作用(至少它不是一个有效的命令),我应该提到这一点。 – northpole 2012-01-11 22:50:16
@northpole:你有没有尝试下载一个副本,例如从http://www.petri.co.il/download_free_reskit_tools.htm并运行它? – Jon 2012-01-11 22:52:46
不,我做了,但是,抓住rktools,并可以使用robocopy工作。但我希望能够使用已安装的命令来完成此操作,这样我就不必下载并安装在每台将要使用它的PC上。 – northpole 2012-01-11 22:55:33
查看答案batch file to delete files older than a specified date一种方式与XCOPY做到这一点。
有了xcopy,你需要指定完整的日期(你不能说“30天前”),但你可以通过其他命令来计算。
编辑 - 添加了日志信息并补偿了一个FINDSTR错误 – dbenham 2012-01-19 02:27:32
非常好,我终于可以检查这个,它会工作。感谢您的努力! – northpole 2012-01-23 00:54:38