用于动态XML数据的XSL样式表

我想创建1个XSL样式表，可以创建具有数据特定标题和列数的HTML表格代码。下面是数据的两个示例性套欲由1个样式表用于动态XML数据的XSL样式表

<root> 
     <row> 
     <postId>1</postId> 
     <id>1</id> 
     <name>name 1</name> 
     <email>[email protected]</email> 
     <body>body 1</body> 
     </row> 
     <row> 
     <postId>1</postId> 
     <id>2</id> 
     <name>name 2</name> 
     <email>[email protected]</email> 
     <body>body 2</body> 
     </row> 
</root> 

<root> 
     <row> 
     <id>1</id> 
     <desc>desc 1</desc> 
     <Note>Note 1</Note> 
     </row> 
     <row> 
     <id>2</id> 
     <desc>desc 2</desc> 
     <Note>Note 2</Note> 
     </row> 
     <row> 
     <id>3</id> 
     <desc>desc 3</desc> 
     <Note>Note 3</Note> 
     </row> 
</root>

处理然后，我想在片材产生类似输出：

<table> 
    <thead> 
    <th>postId</th><th>id</th><th>name</th><th>email</th><th>body</th> 
    </thead> 
    <tbody> 
    <tr> 
     <td>1</td><td>1</td><td>mane 1</td><td>[email protected]</td><td>body 1</td> 
    </tr> 
    <tr> 
     <td>1</td><td>2</td><td>mane 2</td><td>[email protected]</td><td>body 2</td> 
    </tr> 
    </tbody> 

<table> 
    <thead> 
    <th>id</th><th>desc</th><th>Note</th> 
    </thead> 
    <tbody> 
    <tr> 
     <td>1</td><td>desc 1</td><td>Note 1</td> 
    </tr> 
    <tr> 
     <td>2</td><td>desc 2</td><td>Note 2</td> 
    </tr> 
    <tr> 
     <td>3</td><td>desc 3</td><td>Note 3</td> 
    </tr> 
    </tbody> 
</table>

我已想出表头（见下面），但我似乎无法让身体工作。我无法弄清楚如何显示一个元素的值，我不知道这个元素的名称或者是否存在。

<?xml version="1.0"?> 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="root"> 
    <html> 
    <body> 
     <h2>My Table Data</h2> 
     <table border="1"> 
      <thead> 
      <tr bgcolor="#9acd32"> 
       <xsl:for-each select="row[1]/*"> 
       <th><xsl:value-of select ="name(.)"/></th>   
       </xsl:for-each> 
      </tr> 
      </thead> 
      <tbody> 
      ????? 
      </tbody>

来源

2016-11-07 Austin Crapo

如果您row元素始终具有相同数量的元素，并以相同的顺序，你就不必担心名字，和你?????可以简单地用这个来代替....

<xsl:for-each select="row"> 
    <tr> 
     <xsl:for-each select="*"> 
     <td> 
      <xsl:value-of select="." /> 
     </td> 
     </xsl:for-each> 
    </tr> 
</xsl:for-each>

在另一方面，如果row元素可以有不同顺序的元素，甚至缺失，则（假设第一行总是完整的），你可以定义一个变量来保存“标题”行单元格

<xsl:variable name="headers" select="row[1]/*"/>

然后你的????受本...

<xsl:for-each select="row"> 
    <xsl:variable name="currentRow" select="."/> 
    <tr> 
     <xsl:for-each select="$headers"> 
     <xsl:variable name="currentHeaderName" select="name()" /> 
      <td> 
       <xsl:value-of select="$currentRow/*[name() = $currentHeaderName]"/> 
      </td> 
     </xsl:for-each> 
    </tr> 
    </xsl:for-each>

试试这个XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:template match="root"> 
     <html> 
     <body> 
      <h2>My Table Data</h2> 
      <xsl:variable name="headers" select="row[1]/*"/> 
      <table border="1"> 
       <thead> 
        <tr bgcolor="#9acd32"> 
        <xsl:for-each select="$headers"> 
         <th> 
          <xsl:value-of select="name(.)"/> 
         </th>   
        </xsl:for-each> 
        </tr> 
       </thead> 
       <tbody> 
        <xsl:for-each select="row"> 
        <xsl:variable name="currentRow" select="."/> 
        <tr> 
         <xsl:for-each select="$headers"> 
         <xsl:variable name="currentHeaderName" select="name()" /> 
          <td> 
           <xsl:value-of select="$currentRow/*[name() = $currentHeaderName]"/> 
          </td> 
         </xsl:for-each> 
        </tr> 
        </xsl:for-each> 
       </tbody> 
      </table> 
      </body> 
     </html> 
    </xsl:template> 
</xsl:stylesheet>

来源

2016-11-07 14:17:16

非常感谢！ –

用于动态XML数据的XSL样式表

回答

相关问题