粘贴VBA阵列

Question

我有这样的代码，将填充数组

Sub rangearray() 

    Dim arr() As Variant 
    Dim Rng As Range 
    Dim myCell As Range 
    Dim i As Integer 

    Set Rng = ActiveSheet.Range("G10:G14") 

    For Each myCell In Rng 
     ReDim Preserve arr(i) 
     arr(i) = myCell 
     i = i + 1 
    Next myCell 

    ActiveSheet.Range("H10:H14") = arr() 

End Sub 

在这里你可以看到，在监视窗口中值是什么一直在

除了加载，当我将数组添加回工作簿时，它仅粘贴数组的第一个元素。

是否有可能将整个阵列工作表粘贴不通过阵列，具有循环？

UPDATE考虑看看从Sorceri链接后我已经修改了代码使用.Transpose功能，所以我修改的代码现在看起来是这样：

Sub rangearray() 

    Dim arr() As Variant 
    Dim Rng As Range 
    Dim myCell As Range 
    Dim i As Integer 

    Set Rng = ActiveSheet.Range("A1:A5") 

    For Each myCell In Rng 
     ReDim Preserve arr(i) 
     arr(i) = myCell 
     i = i + 1 
    Next myCell 

    ActiveSheet.Range("B1:B5") = WorksheetFunction.Transpose(arr) 

End Sub 

Answer 1

你将要使用的转置工作表功能http://msdn.microsoft.com/en-us/library/office/ff196261.aspx

请参阅下文。你必须将其分配到的范围内的值

Sub rangearray() 

Dim arr() As Variant 
Dim Rng As Range 
Dim myCell As Range 
Dim i As Integer 

Set Rng = ActiveSheet.Range("A1:A5") 

For Each myCell In Rng 
    ReDim Preserve arr(i) 
    arr(i) = myCell 
    i = i + 1 
Next myCell 

ActiveSheet.Range("B1:B5").Value = WorksheetFunction.Transpose(arr) 

End Sub 

Answer 2

正如我在上面，我的评论中提及了你并不需要一个数组，如果你只想要一个阵列的解决方案，那么你执行你想要做的，但仍然是行动不需要长循环填充数组。直接将范围的值分配给数组。它将创建一个您不需要转置的二维数组。

Sub rangearray() 
    Dim arr 
    Dim Rng As Range 

    With ActiveSheet 
     Set Rng = ActiveSheet.Range("G10:G14") 

     arr = Rng.Value 

     .Range("H10").Resize(UBound(arr, 1)).Value = arr 
    End With 
End Sub