删除重复的分隔字符串批次

Question

完成一个快速搜索，但不能到达这个底部。我想从字符串中删除任何重复值，并用逗号分隔值。例如

set _str=1,2,3,1,5,4,2 

处理这将填充一个新的变量与'un-duped'列表。例如

echo %_finalstr% 

将产生：

1,2,3,5,4

增补并发症_STR可以是任何数量的组件（即，它可以是1个值，这可能是200）。它也可以为空。虽然没有特殊字符的问题 - 它将全部采用数字，逗号，数字，逗号等格式。值也可以按任意顺序排列。

任何想法？

Answer 1

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
SET "string=1,2,3,5,4,2" 
CALL :process 
SET "string=1,2,3,5,4,2,1,1,1,1,1,1,1,1,107,221,3,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,13,2,1" 
CALL :process 
SET "string=" 
CALL :process 
SET "string=3" 
CALL :process 
SET "string=3,3" 
CALL :process 
GOTO :eof 

:process 
SET "newstring=," 
IF DEFINED string FOR %%a IN (%string%) DO (SET "newstring=!newstring:,%%a,=,!%%a,") 
SET "newstring=%newstring:~1,-1%" 
ECHO oldstring:%string%: 
ECHO newstring:%newstring%: 
GOTO :EOF 

的另一种方式，利用内置示范

编辑---解释。

将newstring设置为单个逗号。这确保了newstring都以逗号开头和结尾。

for遍历字符串中的每个元素;逗号被视为分隔符。

对于找到的每个元素n，用,代替任何,n,，然后将n,加到最后。

结果：独特元素列表，由,包围 - 因此删除第一个和最后一个字符并完成。

注意delayedexpansion和使用!利于这种方法，但

IF DEFINED string FOR %%a IN (%string%) DO CALL SET "newstring=%%newstring:,%%a,=,%%%%a," 

可以不管delayedexpansion状态下使用。

引用是针对终端空间抑制，遵循标准惯例。

Answer 2

道：

@echo off 
set "$str=1,2,3,1,5,4,2" 

for %%a in (%$str%) do set "##%%a=%%a" 
setlocal enabledelayedexpansion 
for /f "tokens=2 delims==" %%a in ('set ##') do set "$FinalStr=!$FinalStr!,%%a" 
set "$FinalStr=!$FinalStr:~1!" 
echo !$FinalStr! 

Answer 3

下面的批处理文件保存元素的原始顺序，由OP要求：

set _str=1,2,3,1,5,4,2 

的这种处理会填充新的变量与“未受骗名单。例如

echo %_finalstr% 

将产生：

1,2,3,5,4

@echo off 
setlocal EnableDelayedExpansion 

set _str=1,2,3,1,5,4,2 
REM set "_str=" 

set "_finalstr=," 
for %%a in (%_str%) do if "!_finalstr:,%%a,=!" equ "!_finalstr!" set "_finalstr=!_finalstr!%%a," 
set "_finalstr=%_finalstr:~1,-1%" 
echo Oldstring: "%_str%" 
echo Newstring: "%_finalstr%"