AppData \ LocalLow常量？

Question

目前访问LocalLow我用这个：

{%USERPROFILE}\AppData\LocalLow 

但我想知道是否有用于在INNO一组常数，因为这两个Roaming和Local有一个。

Answer 1

AppData\LocalLow没有常数。

您可以使用Pascal脚本来解决它。

要解决“LocalLow”，必须使用SHGetKnownFolderPath。
另请参阅Detect the location of AppData\LocalLow。

由于在Unicode Inno Setup中缺少（广泛的）PChar类型，因此实施涉及很少的黑客行为。

const 
    MAX_PATH = 260; 
    AppDataLocalLowGUID = '{A520A1A4-1780-4FF6-BD18-167343C5AF16}'; 

{ There's no PChar in Unicode Inno Setup, } 
{ pretend the function returns a pointer to an Integer } 
function SHGetKnownFolderPath(rfid: TGUID; dwFlags: DWORD; hToken: THandle; 
    var ppszPath: Integer): Integer; 
    external 'SHGetKnownFolderPath@Shell32.dll stdcall'; 

{ And allow the Integer to be copied to string } 
function StrCpy(Dest: string; Source: Integer): Integer; 
    external 'StrCpyW@Shlwapi.dll stdcall'; 

{ And allow the Integer pointer to be released } 
procedure CoTaskMemFreeAsInteger(pv: Integer); 
    external 'CoTaskMemFree@Ole32.dll stdcall'; 

function GetAppDataLocalLow: string; 
var 
    Path: Integer; 
    I: Integer; 
begin 
    if SHGetKnownFolderPath(StringToGUID(AppDataLocalLowGUID), 0, 0, Path) = 0 then 
    begin 
    { The path should not be longer than MAX_PATH } 
    SetLength(Result, MAX_PATH); 

    StrCpy(Result, Path); 

    CoTaskMemFreeAsInteger(Path); 

    { Look for NUL character and adjust the length accordingly } 
    for I := 1 to MAX_PATH do 
    begin 
     if Result[I] = #0 then 
     begin 
     SetLength(Result, I - 1); 
     Break; 
     end; 
    end; 
    end; 
end; 

---

如果您需要使用非Code部分的路径（Pascal脚本之外），你可以使用一个scripted constant：

[Files] 
Source: myfile.txt; DestDir: {code:GetAppDataLocalLow} 

而且你需要更改功能签名采取虚拟参数：

function GetAppDataLocalLow(Param: string): string; 

Answer 2

例如，删除文件时卸载m LocalLow with INNO：

[UninstallDelete] 
Type: filesandordirs; Name: "{userappdata}\..\LocalLow\MyFile.txt"