Qt qmake：从变量中删除条目

Question

作为Qt项目部署过程的一部分，我需要将几个文件复制到部署文件夹。我的问题是我无法使-= operator工作。我也想根据文件名过滤出特定的文件。

要重现我的问题，我已经创建了一个简单的Qt项目，其.pro文件如下所示（请参阅“的利息部分”）：

TEMPLATE = app 
QT = core 
CONFIG += console 
CONFIG -= app_bundle 
CONFIG += c++11 

SOURCES += main.cpp \ 
myfile1.cpp \ 
myfile1d.cpp 

SOURCES += myfile1.cpp 
SOURCES += myfile1d.cpp 

#portion of interest - start 
FOLDER_PATH = $$_PRO_FILE_PWD_/../files/ 

#add all files present in 'files' folder 
FILES_TO_COPY = $$FOLDER_PATH/* 

#exclude a specific file 
win32:CONFIG(release, debug|release): { 
FILES_TO_COPY -= $$FOLDER_PATH/filecd.txt 
} 

filesToCopy.files = $$FILES_TO_COPY 
filesToCopy.path = $$_PRO_FILE_PWD_/../deploy 

INSTALLS += filesToCopy 
#portion of interest - finish 

我添加了一个“make install的”一步到在Qt Creator项目设置中构建过程。此步骤应查看.pro文件中的INSTALLS变量，并将指定的文件从'files'复制到'deploy'文件夹中。

现在，该文件夹 '文件' 包含以下文件：

• fileb.txt
• filec.txt
• filecd.txt
• filed.txt
• filedd.txt

以下是我想要做的：

1）最初，我希望除'filecd.txt'之外的所有文件都从'文件'复制到'部署'。我正在尝试使用' - ='来排除'filecd.txt'，但我仍然在复制所有文件。

2）我也想根据名字过滤出特定的文件。例如，如果我们处于发布模式，则不应复制文件的调试版本。这应该排除filecd.txt和filedd.txt，它们被模拟为filec.txt和filed.txt的调试版本。

感谢您的任何帮助。

{版本信息：Qt Creator的4.2.1，基于Qt 5.8.0（MSVC 2015年，32位）

试剂盒信息：桌面的Qt 5.8.0 MSVC2015 32位）}

UPDATE： 对于其他试图（通过经验者及审查）做同样的事情，这是我落得这样做：

#add all files present in 'files' folder 
FILES_TO_COPY = $$files($$FOLDER_PATH/*) 

#From these files: fileb.txt filec.txt filecd.txt filed.txt filedd.txt 
#we only want to copy the following files to the deployment folder 
#fileb.txt filec.txt filed.txt 

#i.e., we wish to exclude these files from deployment folder: 
#filecd.txt filedd.txt 
win32:CONFIG(release, debug|release): { 
    #FILES_TO_COPY -= $$FOLDER_PATH/filecd.txt 

    for(iter, FILES_TO_COPY): { 
     #name of one file 
     FNAME = $$iter #/path/to/filecd.txt   

     SEARCH_TOKEN = 'd.txt' 
     SECTIONS = $$split(FNAME, $$SEARCH_TOKEN)#filec d.txt 

     FNAME1 = $$first(SECTIONS) #filec   

     #if 'd.txt' is not part of the filename then split returns 
     #the filename untouched (i.e. FNAME1 would be equal to FNAME, 
     #and should be found in FILES_TO_COPY) 
     #NOTE: If we are unlucky enough to have another file called     
     #'filec' (without any extension) then the search for filecd.txt 
     #will be abandoned.   
     !contains(FILES_TO_COPY, $$FNAME1) : { 
      FILE_EXT = '.txt' 
      FNAME1D = $$join(FNAME1, , , $$FILE_EXT) #filec.txt     
      contains(FILES_TO_COPY, $$FNAME1D): { 
       REDUNDANT_FILES += $$FNAME      
      } 
     } 

    } 
} 

FILES_TO_COPY -= $$REDUNDANT_FILES 
filesToCopy.files = $$FILES_TO_COPY 
filesToCopy.path = $$_PRO_FILE_PWD_/../deploy 
INSTALLS += filesToCopy 

Answer 1

QMAKE执行水珠扩展文件已经被解析之后，因此当FILES_TO_COPY -= ...行被解析，该变量仍然具有未扩展glob值。

相反，使用$$files内置的测试功能来组装文件的列表，你可以然后将其删除：

FILES_TO_COPY = $$files($$FOLDER_PATH/*) 

win32:CONFIG(release, debug|release): { 
    FILES_TO_COPY -= $$FOLDER_PATH/filecd.txt 
}