故障转换XML文档URL

Question

编辑：实例现在包含有我的主文档

大家在所有标签！我只是对XSLT有个简单的问题。我有一个很大的xml文件，其中嵌套了许多<DIMENSION_Id>节点。在每个<DIMENSION_Id>节点中有两个SYN标记：<SYN>String</SYN><SYN>Integer</SYN>我想要做的是将每个DIMENSION_Id的最远的子节点连接到它的所有祖先路径以创建一个URL。

即

<DIMENSIONS VERSION="1.0.0"> 
    <DIMENSION NAME="Category" SRC_TYPE="INTERNAL"> 
     <DIMENSION_NODE ID="1000"/> 
     <DIMENSION_Id> 
      <SYN>Text</SYN> 
      <SYN>Number</SYN> 
      <DIMENSION_Id> 
       <SYN>More Text</SYN> 
       <SYN>Another Number</SYN> 
      </DIMENSION_Id> 
     </DIMENSION_Id> 
    </DIMENSION> 
</DIMENSIONS> 

我写了这个XSLT先获得从父节点的所有信息，然后最后创建一个完整的URL子节点。不幸的是，它只给了我最远的子节点的信息......我不知道如何附加任何其他文本。 （应改为类似：最远的父/接近父/母/ item_selected）

不幸的是它是所有给我当前节点的值....下面是我写的XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text" /> 
    <xsl:template match="/DIMENSION_NODE"> 
     <xsl:for-each select="ancestor-or-self::*"> 
      <xsl:value-of select="@SYN" /> 
      <xsl:text>/</xsl:text> 
      <xsl:value-of select="." /> 
      <xsl:value-of select="@SYN" /> 
      <xsl:text>/</xsl:text> 
      <xsl:value-of select="." /> 
     </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

在此先感谢您的帮助！

Answer 1

编辑：输入样本更接近问题。

有了这个输入：

<DIMENSIONS VERSION="1.0.0"> 
    <DIMENSION NAME="Category" SRC_TYPE="INTERNAL"> 
     <DIMENSION_NODE ID="1000"/> 
     <DIMENSION_Id> 
      <SYN>Text</SYN> 
      <SYN>1</SYN> 
      <DIMENSION_Id> 
       <SYN>More Text</SYN> 
       <SYN>2</SYN> 
      </DIMENSION_Id> 
     </DIMENSION_Id> 
    </DIMENSION> 
</DIMENSIONS> 

两个选项。

1）应用模板和模式，以祖先：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:template match="text()"/> 
    <xsl:template match="SYN[number()!=.]"> 
     <xsl:apply-templates select="ancestor::DIMENSION_Id" mode="output"/> 
     <xsl:value-of select="concat(' ',../SYN[number()=.],'&#xA;')"/> 
    </xsl:template> 
    <xsl:template match="DIMENSION_Id" mode="output"> 
     <xsl:value-of select="concat('/',SYN[number()!=.])"/> 
    </xsl:template> 
</xsl:stylesheet> 

2）使用参数：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:template match="text()"/> 
    <xsl:template match="SYN[number()!=.]"> 
     <xsl:param name="pPath"/> 
     <xsl:value-of select="concat($pPath,' ',../SYN[number()=.],'&#xA;')"/> 
    </xsl:template> 
    <xsl:template match="DIMENSION_Id"> 
     <xsl:param name="pPath"/> 
     <xsl:apply-templates> 
      <xsl:with-param name="pPath" 
           select="concat($pPath,'/',SYN[number()!=.])"/> 
     </xsl:apply-templates> 
    </xsl:template> 
</xsl:stylesheet> 

两个输出：

/Text 1 
/Text/More Text 2 

Answer 2

我猜你想要这个 ：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 

<xsl:template match="DIMENSION_Id[not(DIMENSION_Id)]"> 
    <xsl:apply-templates select="(.|ancestor::DIMENSION_Id)/SYN" mode="gen"/> 
</xsl:template> 

<xsl:template match="SYN" mode="gen"> 
    <xsl:value-of select="concat('/',.)"/> 
</xsl:template> 
<xsl:template match="text()"/> 
</xsl:stylesheet> 

当这个变换所提供的XML文档应用（校正为良好的形成）：

<DIMENSIONS VERSION="1.0.0"> 
    <DIMENSION NAME="Category" SRC_TYPE="INTERNAL"> 
     <DIMENSION_NODE ID="1000"/> 
     <DIMENSION_Id> 
      <SYN>Text</SYN> 
      <SYN>Number</SYN> 
      <DIMENSION_Id> 
       <SYN>More Text</SYN> 
       <SYN>Another Number</SYN> 
      </DIMENSION_Id> 
     </DIMENSION_Id> 
</DIMENSION> 
</DIMENSIONS> 

有用，正确的结果产生：

/Text/Number/More Text/Another Number 

Answer 3

对不起，每个人都感到困惑。我得到了一些帮助，这里是解决方案：

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 

    <xsl:template match="/"> 
     <URLs> 
      <xsl:apply-templates select="//DIMENSION_NODE"/> 
     </URLs> 
    </xsl:template> 

    <xsl:template match="DIMENSION_NODE"> 
     <xsl:call-template name="getPath"> 
      <xsl:with-param name="currentnode" select="."/> 
     </xsl:call-template> 
    </xsl:template> 

    <xsl:template name="getPath"> 
     <xsl:param name="currentnode"/> 
     <xsl:param name="currenttext" select="''"/> 
     <xsl:param name="firstrun" select="1"/> 
     <xsl:choose> 
      <xsl:when test="$currentnode[parent::DIMENSION]"> 
       <URL> 
        <xsl:value-of select="$currenttext"/> 
       </URL> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:choose> 
        <xsl:when test="$firstrun = 1"> 
         <xsl:variable name="gettext"> 
          <xsl:text>/</xsl:text> 
          <xsl:value-of select="concat($currentnode/DVAL/SYN[1],'&#x9;',$currentnode/DVAL/DVAL_ID/@ID)"/> 
         </xsl:variable> 
         <xsl:call-template name="getPath"> 
          <xsl:with-param name="currentnode" select="$currentnode/.."/> 
          <xsl:with-param name="currenttext" select="concat($gettext,$currenttext)"/> 
          <xsl:with-param name="firstrun" select="0"/> 
         </xsl:call-template> 
        </xsl:when> 
        <xsl:otherwise> 
         <xsl:variable name="gettext"> 
          <xsl:text>/</xsl:text> 
          <xsl:value-of select="$currentnode/DVAL/SYN[1]"/> 
         </xsl:variable> 
         <xsl:call-template name="getPath"> 
          <xsl:with-param name="currentnode" select="$currentnode/.."/> 
          <xsl:with-param name="currenttext" select="concat($gettext,$currenttext)"/> 
          <xsl:with-param name="firstrun" select="0"/> 
         </xsl:call-template> 
        </xsl:otherwise> 
       </xsl:choose> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

此外，我在我的XML文件中的错误道歉。