Grails与joinTable的一对多映射

Question

我有两个领域类。一个是“合作伙伴”，另一个是“客户”。客户可以成为合作伙伴的一部分，合作伙伴可以有1个或多个客户：

class Customer { 
    Integer id 
    String name 
    static hasOne = [partner:Partner] 
    static mapping = { 
     partner joinTable:[name:'PartnerMap',column:'partner_id',key:'customer_id'] 
    } 
} 

class Partner { 
    Integer id 
    static hasMany = [customers:Customer] 
    static mapping = { 
     customers joinTable:[name:'PartnerMap',column:'customer_id',key:'partner_id'] 
    } 
} 

但是，每当我尝试看看如果客户是合作伙伴的一部分，就像这样：

我得到以下错误：

org.springframework.dao.InvalidDataAccessResourceUsageException: could not execute query; SQL [select this_.customer_id as customer1_162_0_, this_.company as company162_0_, this_.display_name as display3_162_0_, this_.parent_customer_id as parent4_162_0_, this_.partner_id as partner5_162_0_, this_.server_id as server6_162_0_, this_.status as status162_0_, this_.vertical_market as vertical8_162_0_ from Customer this_]; nested exception is org.hibernate.exception.SQLGrammarException: could not execute query 

看起来好像Grails是想PARTNER_ID是客户查询的一部分，它不...它是在PartnerMap表，这是应该找customer_id，t母鸡从相应的partner_id获取合作伙伴。

任何人有任何线索我做错了什么？

编辑：我忘了提及我正在做这与遗留数据库表。所以我有一个合作伙伴，客户和PartnerMap表。 PartnerMap只有一个customer_id和partner_id字段。

Answer 1

鉴于您想要连接表的方式有很多，我认为标准GORM无法使其成为双向访问客户的合作伙伴。但是，您可以映射连接表与域类和访问的东西，道：

客户：

class Customer { 
    String name 
    def getPartner() { 
     PartnerMap.findByCustomer(this)?.partner 
    } 
} 

合作伙伴：

class Partner { 
    String name 
    def getCustomers() { 
     PartnerMap.findAllByPartner(this)*.customer 
    } 
} 

PartnerMap：

import org.apache.commons.lang.builder.HashCodeBuilder 

class PartnerMap implements Serializable { 

    Partner partner 
    Customer customer 

    boolean equals(other) { 
     if (!(other instanceof PartnerMap)) { 
     return false 
     } 

     other.partner?.id == partner?.id && 
     other.customer?.id == customer?.id 
    } 

    int hashCode() { 
     def builder = new HashCodeBuilder() 
     if (partner) builder.append(partner.id) 
     if (customer) builder.append(customer.id) 
     builder.toHashCode() 
    } 

    static PartnerMap get(long partnerId, long customerId) { 
     find 'from PartnerMap where partner.id=:partnerId and customer.id=:customerId', 
     [partnerId: partnerId, customerId: customerId] 
    } 

    static PartnerMap create(Partner partner, Customer customer, boolean flush = false) { 
     new PartnerMap(partner: partner, customer: customer).save(flush: flush, insert: true) 
    } 

    static boolean remove(Partner partner, Customer customer, boolean flush = false) { 
     PartnerMap instance = PartnerMap.findByPartnerAndCustomer(partner, customer) 
     instance ? instance.delete(flush: flush) : false 
    } 

    static void removeAll(Partner partner) { 
     executeUpdate 'DELETE FROM PartnerMap WHERE partner=:partner', [partner: partner] 
    } 

    static void removeAll(Customer customer) { 
     executeUpdate 'DELETE FROM PartnerMap WHERE customer=:customer', [customer: customer] 
    } 

    static mapping = { 
     id composite: ['customer', 'partner'] 
     version false 
     table 'PartnerMap' 
    } 
} 

既然你'不使用hasMany，你失去了addToXXX动态方法，但你可以拨打PartnerMap.create()来关联两个实例。你也失去了域类中的集合和反引用，但我为这些添加了实用方法。