将PHP加密代码转换为ColdFusion

Question

我有这样的PHP，我希望在ColdFusion中做相同的处理。

function & _encryptMessage($message) { 

    $td = mcrypt_module_open(MCRYPT_RIJNDAEL_256, '', MCRYPT_MODE_CBC, ''); 
    mcrypt_generic_init($td, $this->key, $this->iv); 
    $encrypted_data = mcrypt_generic($td, $message); 
mcrypt_generic_deinit($td); 
mcrypt_module_close($td); 

    return base64_encode($encrypted_data); 
} 

我觉得这只是

encrypt(message,"","AES","Base64") 

但我肯定知道的没有真正的方法，它不手感相当不错，所以我不知道是否有人在那里就足够好指向正确的方向。

更新： 对于信息this answer由Mister Dai，是特别有帮助。

所以MCRYPT_RIJNDAEL_256实际上是指block size not the encryption strength。加密强度仍然是256，因为使用在sha-256处散列的值在PHP中生成密钥和salt。

这是加密呼叫我现在有：

encrypt(arguments.messageXML,instance.key,"AES/CBC/PKCS5Padding","Base64",ivSalt)

不幸的是这炸毁因为ivSalt长度为32个字节（256位）和AES仅期待一个16个字节IV的盐。查看here似乎ColdFusion/Java for AES中的最大块大小是16字节（128位）。我似乎无法了解如何获得256位块大小。任何帮助将不胜感激。

Answer 1

一对夫妇感谢的应该走出去之前，我回答我的问题。感谢Dave Boyer (Mister Dai),Jason Dean和Jason Delmore的帮助。

由于利曾建议我不得不利用充气城堡，重量轻的API，并在Rijndael算法加密引擎存在的。

我结束了一个函数来创建一个Rijndael算法的密码和功能进行加密和解密带有钥匙和iv盐的字符串。

<cfcomponent displayname="Bounce Castle Encryption Component" hint="This provides bouncy castle encryption services" output="false"> 

<cffunction name="createRijndaelBlockCipher" access="private"> 
    <cfargument name="key" type="string" required="true" > 
    <cfargument name="ivSalt" type="string" required="true" > 
    <cfargument name="bEncrypt" type="boolean" required="false" default="1"> 
    <cfargument name="blocksize" type="numeric" required="false" default=256> 
    <cfscript> 
    // Create a block cipher for Rijndael 
    var cryptEngine = createObject("java", "org.bouncycastle.crypto.engines.RijndaelEngine").init(arguments.blocksize); 

    // Create a Block Cipher in CBC mode 
    var blockCipher = createObject("java", "org.bouncycastle.crypto.modes.CBCBlockCipher").init(cryptEngine); 

    // Create Padding - Zero Byte Padding is apparently PHP compatible. 
    var zbPadding = CreateObject('java', 'org.bouncycastle.crypto.paddings.ZeroBytePadding').init(); 

    // Create a JCE Cipher from the Block Cipher 
    var cipher = createObject("java", "org.bouncycastle.crypto.paddings.PaddedBufferedBlockCipher").init(blockCipher,zbPadding); 

    // Create the key params for the cipher  
    var binkey = binarydecode(arguments.key,"hex"); 
    var keyParams = createObject("java", "org.bouncycastle.crypto.params.KeyParameter").init(BinKey); 

    var binIVSalt = Binarydecode(ivSalt,"hex"); 
    var ivParams = createObject("java", "org.bouncycastle.crypto.params.ParametersWithIV").init(keyParams, binIVSalt); 

    cipher.init(javaCast("boolean",arguments.bEncrypt),ivParams); 

    return cipher; 
    </cfscript> 
</cffunction> 

<cffunction name="doEncrypt" access="public" returntype="string"> 
    <cfargument name="message" type="string" required="true"> 
    <cfargument name="key" type="string" required="true"> 
    <cfargument name="ivSalt" type="string" required="true"> 

    <cfscript> 
    var cipher = createRijndaelBlockCipher(key=arguments.key,ivSalt=arguments.ivSalt); 
    var byteMessage = arguments.message.getBytes(); 
    var outArray = getByteArray(cipher.getOutputSize(arrayLen(byteMessage))); 
    var bufferLength = cipher.processBytes(byteMessage, 0, arrayLen(byteMessage), outArray, 0); 
    var cipherText = cipher.doFinal(outArray,bufferLength); 

    return toBase64(outArray); 
    </cfscript> 
</cffunction> 


<cffunction name="doDecrypt" access="public" returntype="string"> 
    <cfargument name="message" type="string" required="true"> 
    <cfargument name="key" type="string" required="true"> 
    <cfargument name="ivSalt" type="string" required="true"> 

    <cfscript> 
    var cipher = createRijndaelBlockCipher(key=arguments.key,ivSalt=arguments.ivSalt,bEncrypt=false); 
    var byteMessage = toBinary(arguments.message); 
    var outArray = getByteArray(cipher.getOutputSize(arrayLen(byteMessage))); 
    var bufferLength = cipher.processBytes(byteMessage, 0, arrayLen(byteMessage), outArray, 0); 
    var originalText = cipher.doFinal(outArray,bufferLength); 

    return createObject("java", "java.lang.String").init(outArray); 
    </cfscript> 
</cffunction> 

<cfscript> 
function getByteArray(someLength) 
{ 
    byteClass = createObject("java", "java.lang.Byte").TYPE; 
    return createObject("java","java.lang.reflect.Array").newInstance(byteClass, someLength); 
} 
</cfscript> 

</cfcomponent> 

doEncrypt和doDecrypt函数是公开可见的，但不是创建rijndael密码的函数。加密和解密函数采用字符串，密钥和ivSalt分别返回加密或解密的字符串。

的createRijndaelBlockCipher需要一个键，ivSalt，一个布尔值到状态的密码是否将被用于加密或解密和块大小，但块的大小默认为256位。这个函数有相当好的评论，所以它应该是有道理的。

底层的UDF（特别感谢Jason Delmore为该块）确保ColdFusion正确地为解密创建一个字节数组。创建字节数组的其他一些方法不起作用，或者以解密或抛出缓冲区损坏错误的结果不一致为结果。

就是这样。当标准AES加密使用128位块和128位密钥被分类到SECRET，192位或更高的TOP-SECRET时，它花费了太多的精力。 256位块和256位密钥只是在顶部。只因为你可以不意味着你应该。

请记住MCRYPT_RIJNDAEL_256是块大小而不是加密级别。加密级别由您传入mcrypt_encrypt的密钥强度设置，增加块大小不会增加加密强度。

Answer 2

http://help.adobe.com/en_US/ColdFusion/9.0/CFMLRef/WSc3ff6d0ea77859461172e0811cbec22c24-7c52.html

你可以做的简单的东西：

<cfset stringName = "variable 1: " & variable1 & " some more text" /> 
<cfset varName = HASH(stringName, "SHA") /> 

，甚至这样的：

<cfset varName = HASH("i want this string to be encrypted", "SHA") /> 

做这样的事情通常是我说的密码存储和其他敏感办数据。

希望链路和/或示例帮助， 惟妙惟肖