如何编写批处理文件/ vbscript将当前日期和时间插入到AssemblyInfo文件中

Question

任何人都可以请我演示如何编写批处理文件/ vbscript以将当前日期和时间插入到AssemblyInfo文件中？

我有一个AssemblyInfo文件，我希望AssemblyDescription属性值是批处理文件执行的时间。

[AssemblyTitle="MyFile"] 
[AssemblyDescription=""] 
[AssemblyVersion="1.1.0"] 

非常感谢提前！

Answer 1

它更容易做到这一点在VBScript：

filename = "..." 

Set fso = CreateObject("Scripting.FileSystemObject") 

Set re = New RegExp 
re.Pattern = "\[AssemblyDescription="".*?""\]" 
re.IgnoreCase = True 

txt = fso.OpenTextFile(filename).ReadAll 
txt = re.Replace(txt, "[AssemblyDescription=""" & Now & """]") 
fso.OpenTextFile(filename, 2).Write txt 

Answer 2

这使用称为从repl.bat一个帮手批处理文件 - http://www.dostips.com/forum/viewtopic.php?f=3&t=3855

输入文件是"AssemblyInfo"，它改写为新的数据。

将"c:\backup folder"更改为您的文件位置。

@echo off 

pushd "c:\backup folder" 

for /f "delims=" %%a in ('wmic OS Get localdatetime ^| find "."') do set "dt=%%a" 
set "YYYY=%dt:~0,4%" 
set "MM=%dt:~4,2%" 
set "DD=%dt:~6,2%" 
set "HH=%dt:~8,2%" 
set "Min=%dt:~10,2%" 
set "Sec=%dt:~12,2%" 

set datestamp=%YYYY%%MM%%DD% 
set timestamp=%HH%%Min%%Sec% 
set fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec% 

type "AssemblyInfo" |repl "^(.AssemblyDescription=).*" "$1\x22%fullstamp%\x22]" mx >"AssemblyInfo.tmp" 
move "AssemblyInfo.tmp" "AssemblyInfo" >nul 
popd 

Answer 3

的经典方式：

@ECHO OFF &SETLOCAL 
FOR /f %%a IN ('^<"file" find /c /v ""') DO SET "lines=%%a" 

SETLOCAL ENABLEDELAYEDEXPANSION 
<file (
FOR /l %%a IN (1,1,%lines%) DO (
    SET "line=" 
    SET /p "line=" 
    IF "!line:AssemblyDescription=!" neq "!line!" (
     SET "line=[AssemblyDescription="!date! !time!"]" 
    ) 
    ECHO(!line! 
))>newfile 
ENDLOCAL