我如何让这个批处理程序更高效

我的一位朋友要求我制作一个程序，可以打印一串随机的1和0的字符串，像时尚的矩阵。我同意了，并成功地编写批处理程序具有所需的输出，但它那种跑的慢，如果有一种方法，我可以使它更有效我如何让这个批处理程序更高效

set count=0 

:loopassign 
if %count%==80 goto show 
set/a count=%count%+1 
set/a value=%random% %% 2 
set number%count%=%value% 
goto loopassign 

:show 
echo {    %number1%%number2%%number3%%number4%%number5%%number6%%number7%%number8%%number9%%number10%%number11%%number12%%number13%%number14%%number15%%number16%%number17%%number18%%number19%%number20%%number21%%number23%%number24%%number25%%number26%%number27%%number28%%number29%%number30%%number31%%number32%%number33%%number43%%number44%%number45%%number46%%number47%%number48%%number49%%number50%%number51%%number52%%number53%%number54%%number55%%number56%%number57%%number58%%number59%%number60%%number61%%number62%%number63%%number64%%number65%%number66%%number67%%number68%%number69%%number70%%number71%%number72%%number73%%number74%%number75%%number76%%number77%%number78%%number79%%number80% } 
set count=0 
goto loopassign

来源

2013-02-12 user2062538

我想知道的主要耗时部分是goto loopassign。
这可以用FOR/L循环代替。

该循环比goto更好，因为在搜索标签时不再需要扫描整个文件。
而for-block内部的代码被缓存并且只被解析一次，因此执行速度更快。

对单个字符使用单个行变量而不是80个变量仅用于可维护性。

@echo off 
setlocal enableDelayedExpansion 
set count=0 

:loopassign 
set "line=" 
for /L %%n in (1,1,80) do (
    set /a "value=!random! & 1" 
    set "line=!line!!value!" 
) 

:show 
echo {    !line! } 
goto loopassign

更多改进的速度变

您可以轻松地加速它更用一个简单的把戏在每个循环四个，而不是一个字符时生成，所以你只需要20环为单行。

for /L %%n in (1,1,20) do (
    set /a "n=!random! & 15,m=10000+(n&8)*125+(n&4)*25+(n&2)*5+(n & 1)" 
    set "ln=!ln!!m:~-4!" 
)

这似乎是快三倍

来源

2013-02-12 20:01:43 jeb

+1，你打败了我，但我无论如何发布了几乎相同的东西，外部无限FOR循环。 – dbenham 2013-02-12 20:20:30

+1对你来说，外环不会显着提高速度，但是轻咬技术快三倍:-) – jeb 2013-02-12 20:37:44

哦 - 这是讨厌的。我喜欢它:)一段时间以来，我认为你可以每循环多达9位数字，但是我记得'％random％'maxes在32767.为什么'＆15'？这似乎是不必要的。 – dbenham 2013-02-12 21:28:19

你应该了解

FOR循环：从命令提示符HELP FOR类型。特别是，您需要FOR/L选项
延迟扩展：类型HELP SET从命令提示符。关于延期扩张的部分大约是帮助的一半。

这是一个使用2个FOR/L循环的解决方案。外循环是无限的，因为它永远不会增加计数器。

@echo off 
setlocal enableDelayedExpansion 
for /l %%Z in (0 0 1) do (
    set "ln=" 
    for /l %%N in (1 1 80) do (
    set /a "n=!random! %% 2" 
    set "ln=!ln!!n!" 
) 
    echo {    !ln! } 
) 
exit /b

来源

2013-02-12 20:16:50 dbenham

我喜欢速度测试程序！我想下面的矿井会更快...

@echo off 
setlocal EnableDelayedExpansion 

rem Create a Decimal-to-Binary conversion table for values from 0 to 15 
set dec=0 
for %%n in (0000 0001 0010 0011 0100 0101 0110 0111 
      1000 1001 1010 1011 1100 1101 1110 1111) do (
    set bin[!dec!]=%%n 
    set /A dec+=1 
) 

rem Repeat the loop 5 times per line 
set line= 
for /L %%n in (1,1,5) do (
    rem Generate 4 groups of 4 bits per cycle 
    set /A "G1=(n=!random!)&15, G2=(n>>=(G1&3)+1)&15, G3=(n>>=4)&15, G4=(n>>4)&15" 
    for /F "tokens=1-4" %%a in ("!G1! !G2! !G3! !G4!") do (
     set line=!line!!bin[%%a]!!bin[%%b]!!bin[%%c]!!bin[%%d]! 
    ) 
) 
echo {    %line%}

安东尼

编辑：我稍微修改了表达，以避免在80二进制位5日线固定位置零。

来源

2013-02-13 01:24:46 Aacini

不错，但我想最高位始终为0，因为％random％只使用15位 – jeb 2013-02-16 11:45:59

@jeb：哎呀，你说得对，jeb！这在80个二进制数字的5个固定位置产生零。我用一个小技巧解决了这个问题;-) – Aacini 2013-02-16 14:36:56

我如何让这个批处理程序更高效

回答

相关问题