XSLT用于从XML文件

Question

移除标签我有这个XML文件：

<?xml version="1.0" encoding="UTF-8" standalone="no"?> 
<results> 
    <output> 
    <status>OK</status> 
    <usage>Please use it</usage> 
    <url/> 
    <language>english</language> 
    <category>science_technology</category> 
    <score>0.838661</score> 
    </output> 
</results> 

我想从这个XML删除标记<output> </output>。

总产值有望

<?xml version="1.0" encoding="UTF-8" standalone="no"?> 
<results> 
<status>OK</status> 
    <usage>Please use it</usage> 
    <url/> 
    <language>english</language> 
    <category>science_technology</category> 
    <score>0.838661</score> 

</results> 

我怎样才能做到这一点？

Answer 1

最短的可能：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="results"> 
    <xsl:copy> 
     <xsl:copy-of select="output/*"/> 
    </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

或使用身份规则：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="results"> 
     <xsl:copy> 
      <xsl:apply-templates select="output/*"/> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

最简单的方式做到这一点（几乎是机械和不假思索）：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="output"><xsl:apply-templates/></xsl:template> 
</xsl:stylesheet> 

当这个转换是一个pplied所提供的XML文档：

<results> 
    <output> 
    <status>OK</status> 
    <usage>Please use it</usage> 
    <url/> 
    <language>english</language> 
    <category>science_technology</category> 
    <score>0.838661</score> 
    </output> 
</results> 

想要的，正确的结果产生：

<results> 
    <status>OK</status> 
    <usage>Please use it</usage> 
    <url/> 
    <language>english</language> 
    <category>science_technology</category> 
    <score>0.838661</score> 
</results> 

说明：

1. 身份规则/模板拷贝每个节点“如同” 。

2. 有一个模板覆盖身份规则。它匹配任何output元素，并防止将其复制到输出中，但会继续处理其任何子元素。

记住：重写身份规则是最基本的和最强大的XSLT设计模式。