是否可以通过多个参数进行optparse-applicative选项？

Question

我刚刚发现我精心打造的解析器无法解析我扔在任何字符串：

roi :: Parser (Maybe ROI) 
roi = optional $ option (ROI <$> auto <*> auto <*> auto <*> auto) 
       $ long "roi" <> metavar "ROI" <> help "Only process selected region of interest" 

其中ROI = ROI Int Int Int Int

如果这是很重要的，它是嵌套在一个更高的解析器

options :: Parser Opts 
options = Opts <$> input <*> output <*> roi <*> startT <*> endT 

其中Opts是一个合适的ADT。

现在我假设roi解析器将解析表达式，如--roi 1 2 3 4，但它失败，并且给我使用消息Invalid argument '128'。

--roi 1而不是解析，但返回Just (ROI 1 1 1 1)

有没有一种方法，使这项工作？

Answer 1

我不认为选项应该消耗多个参数。至少我不确定你会怎样去实现它。我建议你简单地放弃这个想法，然后把你的ROI选项放到一个参数中，使用类似--roi 1,2,3,4的语法。

你会只需要实施一个定制阅读器，这里是你如何能做到这一点的例子：

module Main where 

import Options.Applicative 

data ROI = ROI Int Int Int Int 
    deriving Show 

-- didn't remember what this function was called, don't use this 
splitOn :: Eq a => a -> [a] -> [[a]] 
splitOn sep (x:xs) | sep==x  = [] : splitOn sep xs 
        | otherwise = let (xs':xss) = splitOn sep xs in (x:xs'):xss 
splitOn _ [] = [[]] 

roiReader :: ReadM ROI 
roiReader = do 
    o <- str 
    -- no error checking, don't actually do this 
    let [a,b,c,d] = map read $ splitOn ',' o 
    return $ ROI a b c d 

roiParser :: Parser ROI 
roiParser = option roiReader (long "roi") 

main :: IO() 
main = execParser opts >>= print where 
    opts = info (helper <*> roiParser) fullDesc 

Answer 2

类型的option是：

​​

ReadM，在转向，是“ReaderT字符串以外的新类型”，由选项阅读器使用“。由于option使用ReaderT引擎盖下，当你的ReadM像你这样在这里Applicative情况下使用它...

ROI <$> auto <*> auto <*> auto <*> auto 

...相同，整体而言，输入字符串被提供给每个四个auto解析器，因为这就是读者/函数应用实例的工作方式。

如果您希望将由空格分隔的值分解为单个ROI，则需要编写自定义分析程序。这是一个不太特别的尝试，围绕eitherReader。请注意，这将要求值位于引号（--roi "1 2 3 4"）内，以便将它们作为单个字符串引入。 Cubic的答案提出了一种替代方法，它使用逗号分隔值（--roi 1,2,3,4）。

import Text.Read (readEither) 

-- etc. 

roi :: Parser (Maybe ROI) 
roi = optional 
    $ option (eitherReader $ \inp -> case traverse readEither (words inp) of 
     Right [x, y, z, w] -> Right (ROI x y z w) 
     Right _ -> Left "ROI requires exactly 4 values" 
     Left _ -> Left "ROI requires integer values") 
    $ long "roi" <> metavar "ROI" <> help "Only process selected region of interest" 

成功和失败的模式：

GHCi> execParserPure defaultPrefs (info roi mempty) ["--roi","1 2 3 4"] 
Success (Just (ROI 1 2 3 4)) 
GHCi> execParserPure defaultPrefs (info roi mempty) ["--roi","1 2 3"] 
Failure (ParserFailure (option --roi: ROI requires exactly 4 values 

Usage: <program> [--roi ROI],ExitFailure 1,80)) 
GHCi> execParserPure defaultPrefs (info roi mempty) ["--roi","1 2 foo 4"] 
Failure (ParserFailure (option --roi: ROI requires integer values 

Usage: <program> [--roi ROI],ExitFailure 1,80))