Select Case wrong output＆Mismatch error

Question

虽然我已经编写了一些其他的东西，但我对VBA Excel相对较新。 我想交叉比较1和0之间的一列数字，称为分数，结果可以是取决于数值的4之一。然而，无论我如何编码（我试过只使用“To”或只有“<> =”），我只能得到相同的结果（1），但没有任何效果。我似乎也无法让它通过我的专栏工作，一次只能在一个单元中进行（每当我将范围扩展到“B2：B7”时，它都会给我一个不匹配的错误）。 ，它实际上给我，我在寻找，并通过一列或细胞作用的结果

谢谢您的时间

下面是代码：

Sub Vertical_Analysis() 

    Sheets("Vertical").Select 

    Dim score As Integer 
    score = Range("B2").Value 

    Dim result As String 
    Select Case score 
     Case Is >= 0.15 
      result = "1" 
     Case 0.11 To 0.14 
      result = "0.6" 
     Case 0.08 To 0.1 
      result = "0.3" 
     Case Is <= 0.07 
      result = "0" 
    End Select 

    Range("B21").Value = result 

End Sub 

Answer 1

首先score需要一个双倍不是整数。

然后循环使用For Each。

最后一部分.Range("B21").Offset(i).Value = result将每个结果向下移动一行，以便它们不会相互替换。

试试这个：

Sub Vertical_Analysis() 

    Dim score As Double, result As String 
    Dim Rng As Range, i As Long 

    i = 0 

    With Sheets("Vertical") 
     For Each Rng In .Range("B2:B7") 
      score = Rng.Value 
      Select Case score 
       Case Is >= 0.15 
        result = "1" 
       Case 0.11 To 0.14 
        result = "0.6" 
       Case 0.08 To 0.1 
        result = "0.3" 
       Case Is <= 0.07 
        result = "0" 
      End Select 
      .Range("B21").Offset(i).Value = result 
      i = i + 1 
     Next Rng 
    End With 
End Sub