Windows批处理：“超时”命令模拟

Question

我试图找出如何限制一个Windows批处理文件在内的程序执行时间。有没有像Unix timeout命令？ 请指教。

Answer 1

我刚刚安装了Cygwin并使用了unix-style timeout命令。

Answer 2

我不认为有超时命令。但是，您可以开始在后台执行任务并在超时时间内使用ping（使用ping），然后终止任务。

Answer 3

要限制某个程序运行，你可以做这样的事情

start yourprogram.exe 
timeout /t 10 
taskkill /im yourprogram.exe /f 

启动yourprogram.exe，等待10秒时间，然后杀死该程序。

Answer 4

此代码等待60秒，然后检查％ProgramName％是否正在运行。

要增加此时间，请更改WaitForMinutes的值。

要缩短检查之间的时间间隔，请将WaitForSeconds设置为希望等待的秒数。

@echo off 
set ProgramName=calc.exe 
set EndInHours=2 

:: How Many Minutes in between each check to see if %ProgramName% is Running 
:: To change it to seconds, just set %WaitForSeconds% Manually 
set WaitForMinutes=1 
set /a WaitForSeconds=%WaitForMinutes%*60 

:: How many times to loop 
set /a MaxLoop=(%EndInHours%*60*60)/(%WaitForMinutes%*60) 

REM Use a VBScript popup window asking to terminate %ProgramName% 
echo set WshShell = WScript.CreateObject("WScript.Shell") > %tmp%\tmp.vbs 
echo Wscript.Quit (WshShell.Popup("Click 'OK' to terminate %ProgramName%." ,10 ,"Terminate %ProgramName%", 0)) >> %tmp%\tmp.vbs 

start %ProgramName% 
set running=True 
:: Give time for %ProgramName% to launch. 
timeout /t 5 /nobreak > nul 
setlocal enabledelayedexpansion 
for /l %%x in (1,1,%MaxLoop%) do (
    if "!running!"=="True" for /l %%y in (1,1,%WaitForMinutes%) do (
    if "!running!"=="True" (
     set running=False 
     REM call Pop-Up 
     cscript /nologo %tmp%\tmp.vbs 
     if !errorlevel!==-1 (
     for /f "skip=3" %%x in ('tasklist /fi "IMAGENAME EQ %ProgramName%"') do set running=True 
    ) else (
     taskkill /im %ProgramName% 
    ) 
    ) 
) 
) 
if exist %tmp%\tmp.vbs del %tmp%\tmp.vbs 

该代码使用VBScript创建一个弹出框。单击OK将导致％ProgramName％通过taskkill被杀死。

---

如果你不想使用弹出窗口，可以通过删除使用timeout ...

REM Use a VBScript popup window asking to terminate %ProgramName% 
echo set WshShell = WScript.CreateObject("WScript.Shell") > %tmp%\tmp.vbs 
echo Wscript.Quit (WshShell.Popup("Click 'OK' to terminate %ProgramName%." ,10 ,"Terminate %ProgramName%", 0)) >> %tmp%\tmp.vbs 

...和更换此...

 REM call Pop-Up 
     cscript /nologo %tmp%\tmp.vbs 
     if !errorlevel!==-1 (

...这一点：

 REM Use CTRL+C to kill %ProgramName% 
     timeout /t %WaitForSeconds% /nobreak 
     if !errorlevel!==0 (

使用/nobreak是必要的，因为timeout不区分按键或超时。这将允许您通过按CTRL + C终止％ProgramName％，但这会导致您的批处理文件在您执行操作时询问Terminate batch job (Y/N)?。 Sl//凌乱/讨厌恕我直言。

---

你可以代替用此来替换上面的代码中使用CHOICE：

 REM Using choice, but choice can get stuck with a wrong keystroke 
     Echo [K]ill %ProgramName% or [S]imulate %WaitForSeconds% Seconds 
     Choice /n /c sk /t %WaitForSeconds% /d s 
     if !errorlevel!==1 (

不过的选择带来了它自己的一套限制表中的。首先，如果一个不在其选项中的按键（在这种情况下为s和k）被按下，它将停止倒计时，基本上锁定直到做出正确的选择。其次，SPACEBAR不能作为选择。